// Alex Kluchikov, 2004
// mailto: klkspa[at]ukr.net, aklk[at]mail.ru
// Feel free to modify/use in any form

global_settings
{
noise_generator 3
max_intersections 18
max_trace_level 18
}
              
//Environment sphere              
sphere{0,1000 
 texture{
  pigment{
   gradient y color_map{ 
    [0,color rgb <0.8,0.83,1>]
    [1,color rgb <0.4,0.7,1>]
    }scale 2 translate -y}finish{ambient .4 diffuse .8}scale 1000}

texture{
 pigment{average pigment_map{
 #declare gr=.75;
 #declare ge=3/(1+gr+gr);
 #declare t1=.1;
 #declare t2=.9;
 #declare tr1=-.2;
 #declare tr2=.2;
  [1,bozo translate 1*y color_map{
   [t1,color rgbt < 1,gr,gr,tr1>*ge]
   [t2,color rgbt < 0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate 1*z color_map{
   [t1,color rgbt < gr, 1,gr,tr1>*ge/.85]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]
  [1,bozo translate 1*x color_map{
   [t1,color rgbt < gr,gr, 1,tr1>*ge/.7]
   [t2,color rgbt <  0, 0, 0,tr2>*ge]
  }]
   
 }}scale 0.25 finish{ambient .4 diffuse .8}scale 2500}

 no_shadow
 no_image 
 hollow double_illuminate scale 100}

#declare st=texture{pigment{color rgb<0.83,0.82,0.84>*1.2}
  finish{diffuse 0.85 ambient 0 specular 0.8 roughness 0.03 phong 1.0 brilliance 7.3 phong_size 80  metallic .5 
   reflection{0.6,1.0 metallic}}
  }

#declare area=1; 
#declare areacount=9;
#declare areasize=10;
#declare mul=.7;
#declare le=10;

light_source{        
 -le*z, color rgb <1.0,0.8,0.6>*0.75*mul
#if(area)           
 area_light x*areasize,y*areasize,areacount,areacount jitter adaptive 1 circular orient 
#else
 parallel
#end
 rotate x*35 rotate -y*65
 }

light_source{
 -le*z, color rgb <0.6,0.8,1>*0.75*mul
#if(area) 
 area_light x*areasize,y*areasize,areacount,areacount jitter adaptive 1 circular orient 
#else
 parallel
#end
 rotate x*45 rotate y*145
 }

light_source{
 -le*z, color rgb 0.25*mul
#if(area) 
 area_light x*areasize,y*areasize,areacount,areacount jitter adaptive 1 circular orient 
#else
 parallel
#end
 rotate x*15 rotate y*75
 }


camera{
 location -5*z
 look_at 0
 angle 60
 translate -y*.6
 rotate x*35
 }          

#declare miatha=normal{bozo -.5 scale 1/20
  slope_map{
  [0,<1,1>]
  [.25,<0,0>]
  [.5,<1,0>]
  [.75,<0,0>]
  [1,<1,-1>]
  }
 }

#declare miatha2=normal{gradient z .2 sine_wave}

union{
 torus{.5,.5 scale y*2}
 cylinder{-y,y,.5}
 texture{st normal{miatha}}
 scale 1
}

disc{-1.01*y,-y,16 texture{st pigment{color rgb <.8,.85,1>}
 normal{
  average normal_map{[1,miatha2][1,miatha2 rotate y*90]}scale .3
  rotate y*30 
  }
 } 
 no_shadow
}