// fake_elevation2.pov
// April 2004 Samuel Benge

#declare fuzzy_shadows=off;
#declare global_illumination=off;
global_settings{
 #if(global_illumination=on)
  radiosity{
   count 100 error_bound .25
   pretrace_start .04 pretrace_end .02
   recursion_limit 1
   normal on
   low_error_factor 10
   brightness 1
  }
 #end
 assumed_gamma 1 
}

#default{finish{ambient 0 }}

camera{ 
 fisheye 
 //right x*.7 up y*.7 // use this line for square images
 right x*.5*1.33 up y*.5
 location<0,20,-60>
 look_at 0
 angle 50 
}

light_source{
 <2,1,0>*100000,
 <1 1 .9>*2
 #if(fuzzy_shadows=on)
  area_light y*20,z*20,4,4
  jitter
  adaptive 1
  orient
  circular
 #end
}

#declare disp=
 pigment{
  granite
  scale 120
  rotate y*35
 }


plane{y,0
 pigment{rgb 0}
 #local V=0;
 #while(V<=1)
  texture{
   pigment{disp
    pigment_map{
     [V rgbt<1 1 1 1>]
     [V+.5 rgb V]
    }
   }
   finish{
    ambient(<.05 .1 .3>+.25)/2
    diffuse 1
    brilliance 2
   }
   normal{
    pigment_pattern{disp} 120-V*100
    accuracy 5
   }
   scale< 1+V/1.5, 1, 1+V/1.5 >
   translate y*V*5   
   translate z*-60
  }
  #local V=V+1/80;
 #end
}