// Persistence of Vision Ray Tracer Scene Description File
// File: Base Scene for some particle-tests
// Vers: 3.5
// Date: 16.2.04 (dd.mm.yy)
// Auth: Tim Nikias Wenclawiak
// Last Update: 26.2.04 (dd.mm.yy)

//Homepage:
// www.nolights.de
//Email:
// Tim.Nikias(@)nolights.de

//Notes
//The amount of time the animation is meant to pass is 18 seconds, with my
//original setup that were 450 frames divided by 25 fps.

//Original particles started in a sphere at <-2,3,0> with radius of .1,
//no inital velocity. They get emitted during the first 2 seconds, 5 per frame. In
//the animation the rate of falling due to gravity was <0,-9.81,0> which gets added
//to the particle's velocity according to the timestep in my particle system.

#default{finish{ambient 0}}

global_settings{
 assumed_gamma 1
 max_trace_level 7
 }

sky_sphere{pigment{gradient y color_map{[0 rgb 1][.15 rgb 1][1 rgb z*.3]}scale 2 translate -1}}

camera{location <0,2.5,-6> look_at <0,1,0>}
light_source{<10,30,-5> rgb 1
 parallel point_at <0,0,0>
 }
light_source{<-40,200,-300> rgb <.1,.12,.26> shadowless}
light_source{<30,20,30> rgb <.05,.09,.2> shadowless }

//The objects the system interacts with. The visible objects are somewhat
//smaller so that a particle's center doesn't lie on a visible surface.
//Note that there is one extra plane in front of the camera to stop particles
//from moving out of the FOV
#declare Size=.1;
#declare Environment=
 union{
  plane{y,Size}
  plane{z,-2}
  plane{<-1,-1,0>,Size translate <3,2,0>}
  box{<-3,0,3>-Size,<3,5,3.5>+Size}
  box{<-3.2,0,-3.5>-Size,<-3,5,3>+Size}
  box{<3,0,-3.5>-Size,<3.2,2,3>+Size}
  sphere{0,.5+Size}
  torus{.5,.1+Size translate <0,.9,0>}
  difference{
   cylinder{y*(.8-Size),y*(1+Size),1}
   cylinder{y*(.7-Size),y*(1.1+Size),.5}
   }
  torus{1,.1+Size translate <0,.9,0>}
  difference{
    cone{Cone_Dir+vnormalize(Cone_Dir)*Size,.6+Size,-vnormalize(Cone_Dir)*Size,.4+Size}
    cone{Cone_Dir*1.1+vnormalize(Cone_Dir)*Size,.5-Size,Cone_Dir*-.1-vnormalize(Cone_Dir)*Size,.3-Size}
    translate y*2.1
    } 
  torus{.5,.1+Size translate <0,1.7,0>}
  pigment{rgb 1 transmit .5}
  }

//Visible Environment
#declare Environment2=
 union{
  plane{y,0}
  box{<-3,0,3><3,5,3.5>}
  box{<-3.2,0,-3.5><-3,5,3>}
  box{<3,0,-3.5><3.2,2,3>}
  sphere{0,.5}
  torus{.5,.1 translate <0,.9,0>}
  torus{1,.1 translate <0,.9,0>}
  difference{
   cylinder{y*.8,y*1,1}
   cylinder{y*.7,y*1.1,.5}
   }
  torus{.5,.1 translate <0,1.7,0>}
  pigment{rgb 1}
  finish{
   specular .7 roughness .01
   brilliance 1.5
   }
  }

#declare Cone_Dir=<-2,1,0>;
difference{
  cone{Cone_Dir,.6,<0,0,0>,.4}
  cone{Cone_Dir*1.1,.5,Cone_Dir*-.1,.3}
  translate y*2.1
  pigment{rgbt <1,1,1,.9>}
  interior{ior 1.6}
  finish{
    specular 1 roughness .006
    brilliance 2
    conserve_energy
    }
  no_shadow
  }  

plane{<-1,-1,0>,0 translate <3,2,0>
 pigment{
  bozo scale <.2,.4,.2> color_map{[0 rgbt 1][1 rgbt <1,.9,.9,.6>]}
 }
 interior{ior 1.33}
 finish{
   specular .8 roughness .01
   conserve_energy
   }
no_shadow
}

object{Environment2}

#if (frame_number <= 50)

#declare A=0;
#while (A<5)

//Add a particle here

#declare A=A+1;
#end

#end