// Persistence of Vision Ray Tracer Scene Description File
// File: meteor ball.pov
// Vers: 3.5
// Desc: nickel-iron meteorite
// Date: 2003.8
// Auth: Bob Hughes
// Mail: omniverse@charter.net

/*
global_settings {
	assumed_gamma 1.0
	//radiosity {}
}

// suburban clear sky colors
sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.7,0.65,0.75>]
      [0.025 rgb <0.6,0.6,0.8>]
      [0.05 rgb <0.4,0.6,1.1>]
      [0.15 rgb <0.25,0.55,1.2>]
      [0.4 rgb <0.2,0.45,1.1>]
      [1.0 rgb <0.15,0.35,0.8>]
    }
  }
}

camera {
	location <0,0,-4>
	look_at 0
	angle 50
}

light_source {
	-1000*z,
	1
	rotate <30,30,0>
}

#include "functions.inc"
*/

#declare MeteorPatternDetail=
function {
	pattern {
		crackle form <0.8,0.2,0> offset 0.1
		scallop_wave turbulence 0.2
		scale 0.1
	}
}

#declare MeteorPattern=
function {
	pattern {
		crackle form <0.8,0,0>
		scallop_wave turbulence 0.1
		scale 0.25
	}
}

isosurface {
	function {
		(x*x+y*y+z*z)
		-
		MeteorPattern(x,y,z)*MeteorPatternDetail(x/3,y/3,z/3)
		//*
		//(f_noise3d(x,y,z)*1.5)
	}
	contained_by {
		sphere {0,1}
	}
	accuracy 0.002
	max_gradient 20
	pigment {
		//rgb <0.26,0.3,0.36>
		slope {
			<0,0,-1>,.2,.9 altitude <0,0,.2>,.1,.8
		}
		color_map {
			[0 color rgb <0.3,0.3,0.3>]
			[.33 color rgb <0.3,0.25,0.25>*2]
			[.5 color rgb <0.25,0.35,0.4>]
			[.67 color rgb <0.3,0.45,0.45>*2]
			[1 color rgb <0.35,0.45,0.5>]
		}
	}
	finish {
		ambient 0.03 diffuse 0.2
		specular 0.4 roughness 0.02
		metallic 0.6 brilliance 2.0
		reflection {
			0.01, 0.08
			metallic 0.3
		}
	}
	translate -0.05*y
	ball_at (0,1)
}