// PoVRay 3.5 Scene File " ... .pov"
// created by   ...  
// Date:   ...
//--------------------------------------------------------------------------
#version 3.5;
global_settings { assumed_gamma 1.0 }
global_settings { max_trace_level 10 }//(1...20) [default = 5]
//--------------------------------------------------------------------------
#include "colors.inc"
#include "textures.inc"
#include "stones.inc"


//--------------------------------------------------------------------------
// camera ------------------------------------------------------------------

#declare Camera_1 = camera{location <0, 30, -100> look_at <0,0,30>  } //Long View
#declare Camera_2 = camera{location <-10,3,-10>   look_at <-10,0,0>   } //Side Align View
#declare Camera_3 = camera{location <0,3,-10>     look_at <0,0,0>   } //Main Render View
#declare Camera_4 = camera{location <10,3,-10>   look_at <10,0,0>  } //Right Side Align View
#declare Camera_5 = camera{location <0,.3,5>      look_at <0,0,50>  } //In-Water View
#declare Camera_6 = camera{location <-10,.5,-1>   look_at<10,.5,-1> } //Front Align View
#declare Camera_7 = camera{location <0,5,-20>     look_at <0,0,0>   } //Main Render View #2

camera{Camera_7}   


#declare Grass=off;
#declare Tree=off;

// grass

#if (Grass)
        #declare MyGrass2 = object {
                #include "fgrass2.inc"

                texture {
                        pigment {
                                dents
                                triangle_wave
                                color_map {
                                        [0.0 rgb <0.0, 0.4, 0.1>]
                                        [1.0 rgb <0.1, 0.6, 0.2>]
                                }
                        }
                }
                scale 0.05
        }
        
        #declare MyGrass1 = object {
                #include "fgrass1.inc"
        
                texture {
                        pigment {
                                dents
                                triangle_wave
                                color_map {
                                        [0.0 rgb <0.0, 0.4, 0.1>]
                                        [1.0 rgb <0.1, 0.6, 0.2>]
                                }
                        }
                }
                scale 0.05
        }
#end        

#if (Tree)
        #declare MyTree1 = object {
                #include "MyTree1.inc"
                TREE
        }

        #declare MyTree2 = object {
                #include "MyTree2.inc"
                TREE
        }        
#end        
        
// sun ---------------------------------------------------------------------
light_source{<500,1500,-2500> color White}

sky_sphere { pigment { gradient <0,1,0>
                       color_map { [0.00 rgb <0.6,0.7,1.0>]
                                   [0.35 rgb <0.0,0.1,0.8>]
                                   [0.65 rgb <0.0,0.1,0.8>]
                                   [1.00 rgb <0.6,0.7,1.0>] 
                                 } 
                       scale 2         
                     } // end of pigment
           } //end of skysphere
//--------------------------------------------------------------------------
//---------------------------- objects in scene ----------------------------
//--------------------------------------------------------------------------
                
difference {
        merge {
                //Grass
                plane{<0,1,0>, 0     
                        texture {
                                pigment {
                                        dents
                                        triangle_wave
                                        color_map {
                                                [0.0 rgb <0.0, 0.4, 0.1>]
                                                [1.0 rgb <0.1, 0.6, 0.2>]
                                        }
                                }
                        }
                }
                //Big Box
                box { <-10, -.7,-0.5> <10, .5, 200.5> texture{ T_Grnt18a normal {bumps 0.75 scale 0.015} finish {ambient 0.1 diffuse 0.8} }}
        }
        //Center Cutout
        box { <-9, -.6, 0> <9,  .8, 200> texture{ T_Grnt18a normal {bumps 0.75 scale 0.015} finish {ambient 0.1 diffuse 0.8} }}
}
        

//Water Area
box {
  <-9, -0.6, 0> <9,  0.4, 200>
  material {
    texture {
      pigment { color rgbf <0.2, 0.7, 0.3, 0.5> }
      finish {
        ambient color rgb <0, 0, 0>
        diffuse 0.0
        reflection {
          0.0, 1.0
          fresnel on
        }
        specular 0.8
        roughness 0.0003
      }
      normal {
        bozo 0.7
        scale 0.15
      }
    }
    interior {
      ior 1.3
      media { absorption <0.8, 0.6, 1.0, 0.5> }
    }
  }
}

//End Of Water
   
//Grass - Closest to Furthest 

#if (Grass)

        #declare My_Grass = array[2] { MyGrass1, MyGrass2 }

        #declare OddEven = 0;

        #declare X = 0;
        #while (X <= 20)


                #declare Z = 0;
                #while(Z <= 50)

                        #declare OddEven = ( ! OddEven );

                        object { My_Grass[OddEven] translate <-12.5-(X*5),0,1.9+(Z*5)> }
                        object { My_Grass[OddEven] translate <12.5+(X*5),0,1.9+(Z*5)> }

                        #declare Z = Z + 1;
                #end

                #declare X = X + 1;
        #end
                        
        object { MyGrass2 translate <-12.5,0,-3.1> }
        object { MyGrass1 translate <-7.5,0,-3.1> }
        object { MyGrass2 translate <-2.5,0,-3.1> }
        object { MyGrass1 translate <2.5,0,-3.1> }
        object { MyGrass2 translate <7.5,0,-3.1> }
        object { MyGrass1 translate <12.5,0,-3.1> }
        
        object { MyGrass1 translate <-12.5,0,-8.1> }
        object { MyGrass2 translate <-7.5,0,-8.1> }
        object { MyGrass1 translate <-2.5,0,-8.1> }
        object { MyGrass2 translate <2.5,0,-8.1> }
        object { MyGrass1 translate <7.5,0,-8.1> }
        object { MyGrass2 translate <12.5,0,-8.1> }
        
        object { MyGrass2 translate <-12.5,0,-13.1> }
        object { MyGrass1 translate <-7.5,0,-13.1> }
        object { MyGrass2 translate <-2.5,0,-13.1> }
        object { MyGrass1 translate <2.5,0,-13.1> }
        object { MyGrass2 translate <7.5,0,-13.1> }
        object { MyGrass1 translate <12.5,0,-13.1> }
   
#end   

//NoMoGrass

//Trees

#if (Tree)
  
        object { MyTree1
                scale 7
                translate <10,0,10> }
        object { MyTree2
                scale 7
                translate <-10,0,10> }
#end                                   
   
//NoMoTrees


// sky ---------------------------------------------------------------
plane{<0,1,0>,10000 hollow  // 
      
      texture{ pigment {color rgb<0.2,0.5,0.8>}
               finish {ambient 1  diffuse 0}}
     }
plane{<0,1,0>,1 hollow  // 
      texture{pigment { bozo turbulence 0.65
                        octaves 6  omega 0.7 lambda 2 
                        color_map { [0.0 color rgb <0.95, 0.95, 0.95>]
                                    [0.1 color rgb <0.85, 0.85, 0.85>]
                                    [0.5 color rgbt <1, 1, 1, 1> ]
                                    [1.0 color rgbt <1, 1, 1, 1> ]   }
                        rotate<10,20,0>
                        scale <0.3, 0.4, 0.2>*3 }
              finish {ambient 1 diffuse 0}}
      scale 1000}  
// fog at the horizon     
fog{distance 300000 color White}