#include "colors.inc"    

camera{
    location <-1,1.7,-4> 
    look_at <0,.7,0>
    up y * 1.5
    right x
}

light_source{<2e4,4e4,1e5> color rgb 3 
    //area_light x*1000 y*1000 5 5
    looks_like{ 
        sphere{<0,0,0>,3000 
            pigment {rgb 9} 
        }
    }
   // photon block for a light source
  photons {
    refraction on
    reflection on
    //area_light
  }

} 


union{
    box{<-2,-.5,-1><2,0,1>}
    box{<-1.7,-.2,-.9><-1.4,-2,.9>}
    box{<1.7,-.2,-.9><1.4,-2,.9>}
    texture{
        pigment{marble turbulence 1.3453986
            color_map{
                [0 color Gray50]
                [1 color White]
            }           
        
        }
        normal{
            marble .1 turbulence 1.3453986
        }
        finish{reflection .1}    
        scale .5
    }
    photons{
        target 5.0          // spacing multiplier for photons hitting the object
        refraction on
        reflection on 
                
    //collect off       // ignore photons
    //pass_through      // do not influence photons
  }

    rotate y*-46
}

sphere{<.3,.4,.3>,.4
    pigment{color rgbf<1,1,1,.5>}
    normal{marble .4 turbulence 2.34 scale .4}
    interior{ior 1.34356756}
    finish{reflection .5}
    // photon block for an object
  photons{
    collect off       // ignore photons
    //pass_through      // do not influence photons
  }

}                 


// Create an infinite sphere around scene and allow any pigment on it
sky_sphere {
  pigment {
    gradient y
    color_map { [0.0 color rgb <0.7,0.7,1.0>] [1.0 color blue 0.5] }
  }
  
}

// radiosity (global illumination) settings
global_settings {
  photons {
    spacing 0.01                 // specify the density of photons
    autostop 1
    }
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.04           // end pretrace at this size
    count 50                      // higher -> higher quality (1..1600) [35]
    nearest_count 7               // higher -> higher quality (1..10) [5]
    error_bound 1.8               // higher -> smoother, less accurate [1.8]
    recursion_limit 7             // how much interreflections are calculated (1..5+) [3]
    low_error_factor .1           // reduce error_bound during last pretrace step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
    normal on                   // take surface normals into account [off]
    //media on                    // take media into account [off]
    //save_file "file_name"       // save radiosity data
    //load_file "file_name"       // load saved radiosity data
    //always_sample off           // turn sampling in final trace off [on]
    max_sample 3.0              // maximum brightness of samples
  }
  
}

// uses image color index as height, extends along X-Z axes
// from <0 0 0> to <1 1 1>
height_field {
  png               // the file type to read (tga/pot/pgm/ppm/png/sys)
  "plasma3.png"     // the file name to read
    smooth
    pigment{color White}
    //normal{bumps 3 turbulence 3.3458987 scale 1 } 
    finish{phong .1}
    translate <-.5,-.7,-.5>
    scale<1000,30,1000>
    photons{collect off}
}
  
fog {
  fog_type   2
  distance   200
  color      rgb <.9,.9,1> 
  fog_offset -10
  fog_alt    50
  turbulence 0.8
}   

plane{y,-10 
    texture{
        pigment{color Gray50}
        finish{reflection .7 phong 1}
        normal{bumps 1 turbulence 1.34555}
    }
}