//Render the image with +KFF99 +KC +FT +A


// ==== Standard POV-Ray Includes ====
#include "colors.inc"	  // Standard Color definitions
#include "textures.inc"	  // Standard Texture definitions
#include "functions.inc"  // internal functions usable in user defined functions

// =========Switches========

#declare Cube_on = 0;         
#declare MainCam = 1;

// =========Settings========

global_settings {
    assumed_gamma 1
}

// ========Camera==========

#if (MainCam = 0)
//Test Camera

    camera {
        location  <0, 0, -3> 
        direction z
        right image_width/image_height*x
        look_at   z*1000
    }
    
#else    
//Main Camera
    
    camera {
        orthographic
        location  <0,0,-1>
        direction z
        right image_width/image_height*x
        look_at   z*1000
    }    
     
#end

// ========lights========
#if (MainCam = 0)

light_source {
  <-10, 10, -10> 
  color rgb 1.0  
}

#end

// ========Cube==========

#if(Cube_on =1)

#declare Cube = union{
  cylinder{-0.5*x,0.5*x,.01 translate <0,-.5,-.5> pigment{Red}}//front bottom
  cylinder{-0.5*x,0.5*x,.01 translate <0,.5,-.5> pigment{Red}} //front top
  cylinder{-0.5*x,0.5*x,.01 translate <0,-.5,.5> pigment{Red}}//back bottom
  cylinder{-0.5*x,0.5*x,.01 translate <0,.5,.5> pigment{Red}} //back top
  
  cylinder{-0.5*y,0.5*y,.01 translate <-.5,0,-.5> pigment{Red}}//front left side
  cylinder{-0.5*y,0.5*y,.01 translate <.5,0,-.5> pigment{Red}} //front right side
  cylinder{-0.5*y,0.5*y,.01 translate <-.5,0,.5> pigment{Red}}//back left side
  cylinder{-0.5*y,0.5*y,.01 translate <.5,0,.5> pigment{Red}} //back right side 
  
  cylinder{-0.5*z,0.5*z,.01 translate <-.5,.5,0> pigment{Red}}//top left side
  cylinder{-0.5*z,0.5*z,.01 translate <.5,.5,0> pigment{Red}} //top right side
  cylinder{-0.5*z,0.5*z,.01 translate <-.5,-.5,0> pigment{Red}}//bottom left side
  cylinder{-0.5*z,0.5*z,.01 translate <.5,-.5,0> pigment{Red}} //bottom right side
}

object{Cube}

#end

// =========Shape========
   
#include"Vicky1.inc"

#declare Shape = object{Vicky  scale .15 // scale down to fit into cube
     #if(MainCam = 0)  
        texture{pigment{White}}
     #else
        texture{pigment{White}finish{ambient 1 diffuse 0}}
     #end
}

#declare Min = min_extent(Shape);
#declare Max = max_extent(Shape);

difference{
    object{Shape  translate z*Max.z}
      plane{z , clock/7 inverse}
      plane{z , (clock/7)-.005 }
        texture{pigment{White}}
        finish{ambient 1 diffuse 0}
}