//This disco ball was created by JWV on 17-5-2003


#include "colors.inc"
#include "woods.inc"
#include "textures.inc"
#include "glass.inc"
#include "metals.inc"
global_settings {
    radiosity{}      //optional
    photons {
    spacing 0.005
    autostop 0
    jitter 0
  }}

  
  

  camera {
    location<25,25,25>
    look_at<0,0,0>
  }


light_source {
<-25, 250, -25>  
color White
    media_interaction on
    photons { reflection on }
}
light_source {
<25, 25, 50>  
color White
    media_interaction on  
    photons { reflection on }
}    


background{GreenYellow}



#declare B=1; // width and height of reflecting squares
#declare RMAX=15; //Radius of sphere

#declare BLOKJE=
box{<-B/2, -B/2, -0.1>, <B/2, B/2, 0> texture {T_Chrome_2B}
}


sphere{<0,0,0>, RMAX pigment{Black} finish{diffuse 3}} // creates sphere within the disco ball

//Start of Algoritm
#declare Theta=0;
#while (Theta<pi/2)
#local i=0;
#declare R=RMAX*cos(Theta);
#declare N=int((2*pi*R)/B);
#while(i<360)
object{BLOKJE translate RMAX*z rotate (Theta/pi*180)*x rotate i*y  photons {reflection 0.4 }}
object{BLOKJE translate RMAX*z rotate -(Theta/pi*180)*x rotate i*y photons {reflection 0.4 }}
#local i=i+(360/N);
#end

#declare T=str(Theta/pi,1,1);
#debug concat("Theta = ", T, " pi, is done \n") 
#declare NY=int((2*pi*RMAX)/B);
#declare Theta=Theta+(pi/2)/(NY/4);;

#end
//End of Algoritm 
 
/*
media {    // atmospheric media sample
  intervals 1
  scattering { 0.1, rgb 0.01 }
  samples 1, 100
  confidence 0.1999
  variance 1/1000
  ratio 0.9
}*/
 
sky_sphere {
  pigment {
    bozo
    color_map {
      [0.0 GreenYellow]
      [0.2 GreenYellow]
    }
    scale 0.2
  }
}