// dispersionbug.pov - A scene that demonstrates the dispersion bug.
// Try the scene with all 4 combinations of the following variables.
// All 4 images should be identical if there is no bug!

#if (frame_number=1)
 #declare UseConserve = true;
 #declare UseFresnel = true;
#end
#if (frame_number=2)
 #declare UseConserve = true;
 #declare UseFresnel = false;
#end
#if (frame_number=3)
 #declare UseConserve = false;
 #declare UseFresnel = true;
#end
#if (frame_number=4)
 #declare UseConserve = false;
 #declare UseFresnel = false;
#end

camera { location <0, 3, -3> look_at y angle 50 }

light_source { <0, 50, 30>, color rgb 1 }

plane { y, 0 pigment { color rgb 1 } }

sphere { y, 1

  material {
    texture {
      pigment { color rgbf <1.0, 1.0, 1.0, 1.0> }
      finish {
        specular 0.7
        roughness 0.01
        ambient 0
        diffuse 0
        reflection { 0.0, 0.0
#if (UseFresnel)
          fresnel on
#end
        }
#if (UseConserve)
        conserve_energy
#end
      }
    }
    interior {
      ior 1.5
      dispersion 1.5
      dispersion_samples 10
    }
  }
}