#include "colors.inc"

// +W1600 +H1200 +A0.3 +AM2 +R3

global_settings {
  radiosity {
    pretrace_start 0.08           // start pretrace at this size
    pretrace_end   0.01           // end pretrace at this size
    count 100                     // higher -> higher quality (1..1600) [35]
    nearest_count 7               // higher -> higher quality (1..10) [5]
    error_bound 0.6               // higher -> smoother, less accurate [1.8]
    recursion_limit 2             // how much interreflections are calculated (1..5+) [3]
    low_error_factor .75          // reduce error_bound during last pretrace step
    gray_threshold 0.0            // increase for weakening colors (0..1) [0]
    minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
    brightness 1                  // brightness of radiosity effects (0..1) [1]

    adc_bailout 0.01/2
    //normal on                   // take surface normals into account [off]
    //media on                    // take media into account [off]
    //save_file "file_name"       // save radiosity data
    //load_file "file_name"       // load saved radiosity data
    //always_sample off           // turn sampling in final trace off [on]
    //max_sample 1.0              // maximum brightness of samples
  }
}

camera {
  location <0, 0, -10>
  look_at <0, 0, 0>
  angle 22
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [ 0.0 color rgb <1.0, 0.0, 0.0> ]
      [ 1.0 color rgb <0.0, 0.0, 1.0> ]
    }
    scale 2
    translate -1
  }
}

//light_source { <3, 3, -20>, White }

#declare fn = function {
    pattern {
      bozo
      noise_generator 3
      warp {
        turbulence <1.0, 1.0, 1.0>
        octaves 8
        lambda 2.0
        omega 0.5
      }
    }
}

isosurface {
  function { 2.0 * fn(x, y ,z) - 0.5 * z }
  contained_by { box { <-2.5, -2.0, -1.0>, <2.5, 5.0, 2.0> } }
  threshold 0.5
  accuracy 0.001
  max_gradient 15     // Octaves 4 -> 12, 8 -> 15
        
  texture {
    pigment { White }
    finish {
      ambient 0.0
      diffuse 0.8
    }
  }
}