// Persistence Of Vision Ray Tracer Scene Description File
// File: OldBrickWall.pov
// Version: 1.0b
// Desc: Old brick wall for IRTC Jan-Feb 2003
// Date: 14 February 2003
// Auth: John Guthkelch (Doctor John) <jguthkelch[at]netscape[dot]net>


#version 3.5;

#include "rad_def.inc"

global_settings {
	assumed_gamma 1.0
	noise_generator 3
	radiosity {
		Rad_Settings(Radiosity_OutdoorLight, off, off)
		always_sample no
	}
}

light_source {
	< 7000, 3000,-5000>
	rgb <1.1, 1.1, 1>
}
light_source {
	<-500, 519, 0>
	rgb 0.5
	shadowless
}

camera {
	location  <0.0, 19.0,-800.0>
	direction z*5.1*2  //Zoom in to isolate detail; for full image use z*5.1
	look_at   <0.0, 19.0,  0.0>
}

cylinder {
	<0, -60.9, 0>, <0, -61, 0>, 100000
	texture {
		pigment {colour rgb 0.5}
	}
}

sky_sphere {
	pigment {
		gradient y
		color_map {
			[(1-cos(radians( 80)))/4 color 1]
			[(1-cos(radians(120)))/4 color rgb <0.5, 0.5, 0.7>]
		}
		scale 2
		translate -1
	}
	pigment {
        	bozo
        	turbulence 1.5
        	octaves 10
        	omega 0.5
        	lambda 2.5
        	color_map {
        		[0.0, 0.4 color rgbt<0.75, 0.75, 0.75, 0> color rgbt<0.9, 0.9, 0.9, 0.8> ]
        		[0.4, 0.7 color rgbt<0.9, 0.9, 0.9, 0.8> color rgbt<1.0, 1.0, 1.0, 1.0> ]
			[0.7, 1.0 color rgbt<1.0, 1.0, 1.0, 1.0> color rgbt<1.0, 1.0, 1.0, 1.0> ]
        	}
    		scale <1, 0.3, 5>
    	}
    	pigment {
        	bozo
        	turbulence 0.6
        	octaves 10
        	omega 0.5
        	lambda 2.5
        	color_map {
			[0.0, 0.4 color rgbt<0.75, 0.75, 0.75, 0> color rgbt<0.9, 0.9, 0.9, 0.9> ]
			[0.4, 0.7 color rgbt<0.9, 0.9, 0.9, 0.9> color rgbt<1.0, 1.0, 1.0, 1.0> ]
			[0.7, 1.0 color rgbt<1.0, 1.0, 1.0, 1.0> color rgbt<1.0, 1.0, 1.0, 1.0> ]
        	}
    		scale <1, 0.3, 5>
    	}
	pigment {
        	bozo
        	turbulence 0.8
        	octaves 10
        	omega 0.5
        	lambda 2.5
        	color_map {
			[0.0, 0.4 color rgbt<0.75, 0.75, 0.75, 0> color rgbt<0.9, 0.9, 0.9, 0.9> ]
			[0.4, 0.6 color rgbt<0.9, 0.9, 0.9, 0.9> color rgbt<1.0, 1.0, 1.0, 1.0> ]
			[0.6, 1.0 color rgbt<1.0, 1.0, 1.0, 1.0> color rgbt<1.0, 1.0, 1.0, 1.0> ]
		}
		scale <1, 0.3, 5>
    	}
}

#declare BrickShape= pigment {
	boxed
	poly_wave 1.2
	colour_map {
		[0 colour rgb 0]
		[0.3 colour rgb 1]
	}
	turbulence 0.05
	scale <0.5, 0.125, 0.125>
	translate <0.55, 0.175, 0>
	warp {
		repeat x*1.05
	}
	warp {
		repeat y*0.6
	}
}

#declare F_Wall= function {
	pigment {
		pigment_pattern {
			gradient y
			turbulence 0.1
			warp {
				repeat y
			}
			scale <1, 0.6, 1>
		}
		pigment_map {
			[0.5, BrickShape
			warp {
				turbulence <0.07, 0.1, 0.015>
				octaves 6
				lambda 0.5
				omega 0.5
			}
			translate <0, -0.025, 0>
			]
			[0.5, BrickShape
			warp {
				turbulence <0.07, 0.1, 0.015>
				octaves 6
				lambda 0.5
				omega 0.5
			}
			translate <0.55, 0.275, 0>
			]
		}
	}
}

#declare OldWall=height_field {
	function 1000, 1000 {
		pigment {
			function {
				F_Wall(x, y, z).gray
			}
			pigment_map {
				[0, granite 
				scale 0.025
				colour_map {
					[0, rgb 0.3]
					[1, rgb 0.45]
				}
				]
				//This bit is what produces the scarring
				[0.075, crackle
				metric 1
				form <0, 0, 1>
				scale <1, 1, -3>
				turbulence 0.3
				colour_map {
					[0, rgb 0.04]
					[1, rgb 0.5]
				}
				]
			}
			scale 0.04
		}
	}
	smooth
	translate -0.5
	rotate <-90, 0, 0>
	scale <160*4/3, 160*4/3, 5>
	texture {
		pigment {
			// or use colour rgb <0.99, 0.99, 0.824>
			image_map 
				{
				png "graffiti.png"
			}
			translate <0.5, 0.5, 0>
			scale <160*4/3, 160, 1>
		}
		finish {
			ambient 0
			diffuse 0.8
			specular 0.4
			roughness 0.01
			
		}
		normal {
			granite 0.25
		}
	}

}

object {
	OldWall
	translate <0, 19, 0> //matches positions in IRTC file
}