// Persistence of Vision Ray Tracer Scene Description File
// File: Rad_Blocks.pov
// Desc: Radiosity-Focal Blur scene file
// Date: January 2003
// Auth: Andrew Cocker
// Run with Screen Ratio 2:1 ie. +w720 +h360

// For Benchmark, use +AM2 +A0.15 +R2 -J +w720 +h360


#version 3.5;


#include "rand.inc"


#declare Rad_On=on;
#declare reflec=on;
#declare foc=on;
#declare my_dif=0.1;
 
global_settings {
  assumed_gamma 1.0 
  max_trace_level 12
//---------------------
#if (Rad_On)
        radiosity{
        pretrace_start 0.16
        pretrace_end   0.01
        count 300             
        nearest_count 4      
        error_bound 0.1      
        recursion_limit 1    
        low_error_factor 1  
        gray_threshold 0.0  
        minimum_reuse 0.015 
        brightness 1.2      
        adc_bailout 0.01/2
        media off  
        } 
#end        
//-----------------

}

camera {
  location  <0.0, 4.0, -17>*1.8//<13.0, -16.0, 6.0>*1.2
  right     x*image_width/image_height
  look_at   <0.0, 0.0, -8.0>
  angle 65
#if (foc)
  aperture 0.8
  focal_point <0,0.5,0>
  blur_samples 180 
#end  
}

#if (Rad_On)
#else
light_source {
  <2000, 3000, 2700>
  color rgb <1.7, 1.5, 1.2>*0.7

}

light_source {
  <-2000, 3000, 2200>
  color rgb <1.2, 1.5, 1.9> *0.1
  shadowless
}
#end

#declare Amount=1.2;



sky_sphere{
	pigment{
		gradient y poly_wave 2 color_map{
			[0 rgb <0.7,0.8,1>*0.5*Amount][0.75 rgb 1*Amount][1 rgb 1*Amount]
		} 
			translate -y*0.5 scale 2}
}


// ----------------------------------------

#declare T_Env=
  texture {
    pigment { color rgb 1.4}
    finish { ambient 0.00 diffuse 1 }
  }


#declare TT= seed(7);

 

//----------
#declare Tex=
  material {
  interior { ior 1.4}
  texture {
    spherical
    texture_map {
    [0.0 T_Env finish { ambient 1.2}]
    [0.3 pigment {rgb <.5,.2,0>} finish {ambient 0 specular 0 diffuse my_dif*8 #if (reflec) reflection {0.3,0.8 fresnel}#end }]
    [0.5 pigment {rgb 0} finish {ambient 0 specular 0 diffuse my_dif #if (reflec) reflection {0.3,0.8 fresnel} #end}]
    [0.675 T_Env finish {#if (reflec) reflection {0.2,0.4 fresnel} #end}]
    [0.775 T_Env finish {diffuse 1}] 
      }
      }
    scale 20
    }
//----------

plane { y, -2 interior {ior 1.2} texture { T_Env }}

#declare LR=40;
#declare IO=40;

union {
#declare CO=1;
#while (CO<=LR)
  #declare CI=1;
  #while (CI<=IO)
     
  box {<RRand (-0.46,-0.475,TT),0,RRand (-0.46,-0.475,TT)>,<RRand (0.46,0.475,TT),RRand(0.2,3,TT),RRand (0.46,0.475,TT)> 
                                //pigment { rgb <RRand (0.8,1,TT),RRand (0.8,1,TT),RRand (0.8,1,TT)> } 
                                rotate <RRand (-4,4,TT),0,RRand (-4,4,TT)>
                                translate <CO-(LR/2),-2,CI-(IO/2)>}
  
  #declare CI=CI+1;
  #end
#declare CO=CO+1;
#end

material {Tex}
}