// Testing two ways of blurred reflection, POV-Ray 3.5.


global_settings { assumed_gamma 1 adc_bailout 1/64 max_trace_level 3 }

camera { location <-7,9,-12> look_at 0 angle 36 }

#declare Sun_Pos=<-100,100,-5>;
light_source { Sun_Pos, 3
	looks_like { sphere { 0,25 pigment { rgb 1 } finish { ambient 4 } } }
}

light_source { <200,400,-200>, <0,.3,.5> shadowless }

sky_sphere { pigment { spherical
	pigment_map { [ .3 rgb <.2,.2,1> ] [ .96 rgb <.7,.75,.82>*1.3 ] [ 1 rgb 4 ] }
	scale 1.5 translate vnormalize( Sun_Pos ) }
}

plane { y,-1
	pigment { checker rgb .25, rgb .1 scale 2 }
	finish { ambient 0 }
}




// Uncomment for method one,
// and put this in the INI window: +AM2 +A0.0 +R3 -J

/*
#declare Blur_Texture = texture {
	pigment { rgb 1 }
	finish { reflection .2 reflection_exponent .7 diffuse .1 ambient 0 }
	normal { bumps .15 scale .00001 }
}
*/




// Uncomment for method two,
// and anti-alias is not necessary.

/*
#declare The_Texture = texture {
	pigment { rgb 1 }
	finish { reflection .2 reflection_exponent .7 diffuse .1 ambient 0 }
	normal { bumps .15 scale .00001 }
}

#declare Blur_Texture = texture { average texture_map {
	#local Cnt=0;
	#while (Cnt<1)
		[ The_Texture translate Cnt*.1 ]
		#local Cnt=Cnt+1/32;
	#end
}};
*/



torus { 2, .5 rotate 90*x texture { Blur_Texture } translate 1.5*y }
torus { 2, 1 rotate 90*z texture { Blur_Texture } translate -.5*y }

sphere { <-4,0,-1.5>, 1 texture { Blur_Texture } }
sphere { <6.5,0,2>, 1 texture { Blur_Texture } }