//Basic fractal parameters
//Centre, initial zoom factor, final zoom factor (magnification factor 2^zoom)

#declare xpos=-0.74715422832175450;
#declare ypos= 0.08760084826232911;
#declare startzoom=0;
#declare endzoom=45;


//Min and max "Maximum iterations" - ie in this case the first frame has a max of 500 iterations, final frame uses a max of 32000.

#declare miniter=500;
#declare maxiter=32000;


//I forget why I made it work this way, but obviously a linear increase was not viable.  I should learn to comment more :)
//iter is the number of iterations used in the current frame
 
#declare iter=(pow(clock,4-(clock*3))*(maxiter-miniter))+miniter;


//The following loops make the current frame's zoom factor, accelerating and decelerating at the beginning and end.
//No doubt this could be reduced to a single formula, but the computational overhead this way is not exactly enormous anyway.

#declare zoom=startzoom;

#declare loop=0;
#while (loop<(frame_number/final_frame))

        #switch (loop)
                #range (0,0.05)
                        
                        #declare zoom=zoom+((loop/0.05)*((endzoom-startzoom)/final_frame));
                
                        #break
                
                #range (0.05000001,0.949999999)
                
                        #declare zoom=zoom+((endzoom-startzoom)/final_frame);
                
                        #break
                
                #range (0.95,1)
                
                        #declare zoom=zoom+(((1-loop)/0.05)*((endzoom-startzoom)/final_frame));
                
                        #break
                        
                #end
                        
        #declare loop=loop+(1/final_frame);
        #end
        
#declare zoom=zoom/0.95;


#declare fractalcolours=color_map {[0.00 color rgb<0,0,0>]
                                   [0.025 color rgb<1,1,1>]
                                   [0.05 color rgb<0,0,0>]
                                   [0.10 color rgb<1,0.133,0.114>]    //Red
                                   [0.15 color rgb<1,0.133,0.114>]
                                   [0.20 color rgb<0,0,0>]
                                   [0.225 color rgb<1,1,1>]
                                   [0.25 color rgb<0,0,0>]
                                   [0.30 color rgb<0.667,0.439,0.753>]          //Mauve  
                                   [0.35 color rgb<0.667,0.439,0.753>]
                                   [0.40 color rgb<0,0,0>]
                                   [0.425 color rgb<1,1,1>]
                                   [0.45 color rgb<0,0,0>]
                                   [0.50 color rgb<0,0.451,0.808>]    //Blue
                                   [0.55 color rgb<0,0.451,0.808>]
                                   [0.60 color rgb<0,0,0>]
                                   [0.625 color rgb<1,1,1>]
                                   [0.65 color rgb<0,0,0>]
                                   [0.70 color rgb<0,0.808,0.380>]            //Green
                                   [0.75 color rgb<0,0.808,0.380>]
                                   [0.80 color rgb<0,0,0>]
                                   [0.825 color rgb<1,1,1>]
                                   [0.85 color rgb<0,0,0>]
                                   [0.90 color rgb<1,1,0.121>]        //Yellow
                                   [0.95 color rgb<1,1,0.121>]
                                   [1.00 color rgb<0,0,0>]       
                                   }

plane {<0,0,1>,0 pigment {mandel iter interior 0,1 exterior 1,1 color_map {fractalcolours} frequency 1+sqrt(iter/1600)} finish {ambient 1 diffuse 0} hollow}

camera {location <0,0,-1> look_at <0,0,0> angle 128/(pow(2,zoom)) rotate <0,0,0> translate <xpos,ypos,0>}