//Title: Big Blown Blob
//Description:
// a  thin shelled blob of glass spheres
// an animation takes a while, but is quite cool (comment out the photons) 
// set clock to 1.2 for a good still

/* Use this as the INI for an animation:
    
[320X240 no AA]
-w320 -h240 +ki0 +kf2 +kfi1 +kff60

*/ 

//render to clock = 3.5 for full effect if you want by switching +kf2 to +kf3.5
//change +kff60 to +kff90 if you do this though

//Author: Ben Scheele
//Date: 12-4-2002

//global_settings { photons{spacing .01}}              

camera{
  ultra_wide_angle 
  location -6.67*z
  look_at x*2*sin(clock*pi/2)
  angle 120
} 

background{ rgb <.77,.99,1.1> }

light_source{ 500*y rgb x photons{refraction on}}
light_source{ <0,2,-5>*100 rgb 1 photons{refraction on}}


#macro twixxler(r,pg) 

blob{ threshold .6

#declare b = 2.5*clock;
#declare st = 1.5+3*clock;

#declare X = -10;
#declare EndX = 10;
#declare Step = 1.5;

#while (X <= EndX)
  
  #declare rot = 20*X*x+clock*20*y; 
                                
   sphere{ <X,-b, 0>, r, st rotate rot}
   sphere{ <X, b, 0>, r, st rotate rot}
   sphere{ <X, 0, b>, r, st rotate rot}
   sphere{ <X, 0,-b>, r, st rotate rot}

#declare X = X + Step;
#end


  interior {
    ior 1.5  
    caustics 3
    fade_distance 1.5
    fade_power 20
  } 

  pigment{ rgb pg transmit 0.9 }
  
  finish { 
      specular 0.7 roughness 0.001 brilliance .004
      phong .3 diffuse .8 ambient .05
      reflection { 0.2, 0.75 falloff .8 metallic .3 }
      conserve_energy
    }

photons{target refraction on}           
}  

#end

difference{
  twixxler(1.3, <1,1,0>)
  twixxler(1, <0,1,1>)
}