// Persistence of Vision Ray Tracer Scene Description File
// File: varnish_test.pov
// Vers: 3.5
// Desc: Checkered Floor Example
// Date: 10/04/02
// Auth: norbert-werner.kern@t-online.de
//

#version 3.5;

#declare Save_Rad  = 0;  
#declare RAD       = 2;  
                
global_settings {
        #declare a_g = 1;
        assumed_gamma a_g
        max_trace_level 5
        noise_generator 2
        ambient_light 0  
        #if(RAD > 0)
                radiosity {
                        pretrace_start 1
                        pretrace_end   1
                        count 30*RAD                
                        nearest_count 1      
                        error_bound 0.5/RAD      
                        recursion_limit 1      
                        gray_threshold 0  
                        minimum_reuse 0.015 
                        brightness 1      
                        adc_bailout 0.005
                        normal on
                        media on
                        #if (Save_Rad = 1)
                                save_file "pov.rad"
                        #else
                                #if (Save_Rad = 2)
                                        load_file "pov.rad" 
                                        always_sample off
                                #end
                        #end                          
                }
        #end
}        

#declare diff = 1;

#if (RAD > 0)
        #default {finish {ambient 0 diffuse diff*0.7}}
        #declare amb = 0;
#else
        #declare amb = 1;
#end

#declare cam_loc = <0.0,2.5,-2.0>;
#declare lookat = <0.0,0.0,-0.5>;
camera {
        ultra_wide_angle 
        location cam_loc 
        right x*image_width/image_height 
        up y 
        look_at lookat 
        angle 65
}


light_source {<-30,30,-30>,<1,0.836,0.567>*7/diff} 

#macro G(Color,g)
        rgb <pow(Color.x,g),pow(Color.y,g),pow(Color.z,g)>
#end 

#declare Gamma = 2.2/a_g;

sky_sphere {
        pigment {
                gradient y 
                color_map {
                        [0.0000 color G(<212,221,239>/255,Gamma)]
                        [0.1029 color G(<219,229,244>/255,Gamma)]
                        [0.1512 color G(<233,241,250>/255,Gamma)]
                        [0.1949 color G(<223,239,252>/255,Gamma)]
                        [0.2444 color G(<201,227,252>/255,Gamma)]
                        [0.2921 color G(<180,213,250>/255,Gamma)]
                        [0.3732 color G(<144,180,239>/255,Gamma)]
                        [0.4255 color G(<137,172,235>/255,Gamma)]
                        [0.7067 color G(< 97,126,198>/255,Gamma)]
                        [0.7740 color G(< 92,119,190>/255,Gamma)]
                        [0.8275 color G(< 88,114,185>/255,Gamma)]
                        [0.8850 color G(< 85,111,180>/255,Gamma)]                        
                        [0.9425 color G(< 82,107,175>/255,Gamma)]                        
                        [1.0000 color G(< 79,103,170>/255,Gamma)]
                }
        }
}

plane {              
        y, -1
        texture {
                pigment {
                        checker
                        color rgb 1
                        color rgb 0.05
                        scale 0.5
                }
        }
}

torus {
        1.2,0.4
        //  interesting part
        texture {
                pigment {
                        slope {lookat-cam_loc,0,0.55}
                        color_map {
                                [0   rgb <1.5,0,0>]
                                [0.2 rgb <0.7,0,0>]
                                [1   rgb <0,0,0.2>]
                        }
                }
                normal {facets coords 0.01}
                finish {
                        ambient 0  
                        diffuse 0.5
                        phong 10
                        phong_size 900
                        brilliance 3.5
                        reflection {0.1,0.6 fresnel on metallic 0.5}
                        metallic 0.65
                }
        }
        //  end interesting part 
        translate y*-0.3
}