// Persistence of Vision Ray Tracer Scene Description File
// File: shadowed checker illusion.pov
// Vers: 3.5
// Desc: checker A is same shade of gray as checker B (or very close), illusion by Edward H. Adelson
// Date: 2002.721
// Auth: bob hughes
// Mail: omniverse@charter.net
// Note: to see the illusion really is just an illusion you could edit the image
//       using a selection tool, Edit|Copy then Edit|Paste, and move one checker
//       next to the other. Or if you have a color-picker (eyedropper) you can
//       compare the RGB values. Even blocking off all but the two labeled checkers
//       by using a paper with holes in it you can tell they are the same.


//cmd:+a0.2 +r2 +am2


#version 3.5;


global_settings
{
        radiosity
        {
                count 67
                error_bound 0.05
                recursion_limit 2
        }
}


camera
{
  location  <3, 5, -7>
  right     x*image_width/image_height
  look_at   <0,-0.5,0>
  angle 42
}

light_source {
   -50*z, 1
   area_light 10*x,10*y,12,12 jitter adaptive 2
  // parallel
  // point_at <0,0,0>
  rotate <30,230,0>
}


plane
{
        y,-0.5
        clipped_by
        {
                sphere {0,67}
        }
        pigment
        {
                color rgb 0.75
        }
        finish
        {
                ambient 0.15 diffuse 0.667
        }
}

sphere
{
        0,67
        pigment
        {
                color rgb 0.75
        }
        finish
        {
                ambient 0.15 diffuse 0.667
        }
}

box
{
        -1,1
  scale <3,0.25,3>*0.999
  translate -0.5*y
  pigment { checker color rgb 0.4 color rgb 0.645 scale <1,2,1>}
  finish  { ambient .1 diffuse .7 }
}

intersection
{
text
{
        ttf
        "arial.ttf",
        "A=B",
        1,
        0
        scale 0.667
        translate <0.75,1,0>
}
superellipsoid
{
        <1,0.1>
        rotate 90*x
        scale <1.25,1,1.25>
        translate <1.5,0.75,1.5>
}
  pigment { color rgb <0.7,0.8,0.9> }
  finish  { ambient .2 diffuse .6 }
}

difference
{
superellipsoid
{
        <1,0.1>
        rotate 90*x
        scale <1.25,1,1.25>
        translate <1.5,0.75,1.5>
        pigment
        {
                color rgb <0.7,0.6,0.5>
        }
        finish
        {
                specular 0.7
                roughness 0.03
        }
}
text
{
        ttf
        "arial.ttf",
        "A=B",
        1,
        0
        scale 0.667
        translate <0.75,1,0>
  pigment { color rgb <0.7,0.8,0.9> }
  finish  { ambient .2 diffuse .6 }
}
}

text
{
        ttf
        "arial.ttf",
        "A",
        1,
        0
        scale 0.333
        rotate 90*x
        translate <-0.6,-0.249,-0.6>
  pigment { checker color rgb 0.63 color rgb 0.41 scale <1,2,1>}
  finish  { ambient .1 diffuse .7 }
}

text
{
        ttf
        "arial.ttf",
        "B",
        1,
        0
        scale 0.333
        rotate 90*x
        translate <1.4,-0.249,-1.6>
  pigment { checker color rgb 0.63 color rgb 0.41 scale <1,2,1>}
  finish  { ambient .1 diffuse .7 }
}