/*
Contains the textures for Step 1 and 2
The textures for Step 1 are the ones you'll
see in the final image

There is only one texture for Step 2(Info_tex).
It is used to get the information about the normal
and the distance to the camera into the image produced in Step 2.
This information is necessary to draw the lines at the edges
*/                                             

#declare Something_tex=
texture{
  pigment{rgb<1,0.1,0.1>}
  finish{ambient 0.6 diffuse 1 brilliance 0}
}

#declare Ground_tex=
texture{
  pigment{rgb<0.8,0.85,1>}
  finish{
    ambient 0.3 diffuse 1 brilliance 4 
    specular 0.5 roughness 0.01 metallic
  }  
}


#declare Info_tex=
  texture{
    pigment{
      average
      pigment_map{
        [ 
          spherical scale Scene_scale translate Cam_pos
          color_map{
            [0 rgb 0]
            [1 red 3 /*transmit 4/3*/]  
          }
        ]
        [
          slope{VPerp_Adjust(x,Cam_pos-Cam_look_at)}
          color_map{
            [0 rgb 0]
            [1 green 3 /*transmit 4/3*/]
          }        
        ]
        [
          slope{VPerp_Adjust(y,Cam_pos-Cam_look_at)}
          color_map{
            [0 rgb 0]
            [1 blue 3 /*transmit 4/3*/]
          }
        ]      
      }
    }  
    finish{diffuse 0 ambient 1}  
  }