#declare Pho =yes;
#declare Rad = yes;

#default{finish{ambient 0 diffuse 0.65}}


global_settings {
  adc_bailout 0.00001
  ambient_light 1
  assumed_gamma 1.8
  max_trace_level 25
  #if (Rad)
    radiosity{
      pretrace_start 0.08
      pretrace_end 0.04
      count 100//500
      recursion_limit 5
      nearest_count 10
      error_bound 1.8//.5
      media on
      low_error_factor .5
      minimum_reuse 0.0001
      brightness 1//0.75
      adc_bailout 0.00001
    }
  #end
  #if (Pho)
    photons{
  	  spacing 0.01
      //count 500000
  	  radius 2
      autostop 0
      max_trace_level 5
    }       
  #end
}

//Final Position
#declare LO=<0,5,-18>;
#declare LA=<0,5,0>;

camera {
  up y
  angle 42
  location LO
  look_at  LA
  right x*image_width/image_height
}

//
// *******  L I G H T S *******
//


/*
box { // Light glare
  -1,1
  hollow
  material{
    texture{pigment{rgbt 1}}
    interior{
    media {
      intervals 10
      samples 1,1
      confidence 0.9
      variance 1.0/128
      ratio 0.9
      emission rgb 20.0
      method 3
      density{
        boxed
        poly_wave 2
      }
    }
    }
  }
  scale <2.2,2,2.2>
  translate y*10
  no_shadow no_image
}
*/

#declare als=12;//size of light grid - als x als

#declare i=0;#while (i<als)
  #declare j=0;#while (j<als)

    light_source {0 rgb 1/pow(als,2)
      spotlight
        point_at  -y
        falloff    100
        radius     10//1.1000  // inner radius
        tightness  0.0//15             
      fade_power 2
      fade_distance 11
      
      #if (als >1)
        translate <-1.4+i*2.8/(als-1),0,-1.4+j*2.8/(als-1)>
      #end
      translate  9.99*y
      photons{refraction on reflection on}
    }

  #declare j=j+1;#end
#declare i=i+1;#end

//
// ********  MATERIALS  *******
//

#include "test room.inc"

//
// ********  OBJECTS  *******
//


box { // Light
  <-1.49, 0.15, -1.49>, <1.49,1, 1.49>
  texture{      
     pigment{rgb 1}      
     finish{ambient 5}
  }
  translate y*10
  no_shadow
}

#declare tt=pow(als,2);

sphere { // Big_Metal_Ball
  <1.65,1.72,1.9>,1.72
  material{Polished_Chrome}
  photons{
      target tt
      reflection on
      refraction off
  }     


}


sphere { // Small_Metal_Ball
  <3.92,1,-3>,1
  material{Polished_Chrome}
  photons{
      target tt
      reflection on
      refraction off
  }     
}

sphere { // Medium_Metal_Ball
  <-0.95, 1.15, -3.849> 1.15
  material{Polished_Chrome}
  photons{
      target tt
      reflection on
      refraction off
  }     
}


sphere { // Glass_Ball
  <-2.62, 1.70, -1.15> 1.70
  material{MGlass}
  photons{
      target tt
      reflection on
      refraction on
      collect off
  }     
}


sphere { // Glass_Ball
  <2.95, 5.9, -0.4> 1.70
  material{MGlass}
  photons{
      target tt
      reflection on
      refraction on
      collect off
  }     
}




box { // Front_Wall
  <-6, 0, -26>, <6, 10,-5>
  material{MWhite}
  interior_texture {pigment{rgbt 1}}
  hollow
}


box { // Left_Wall
  <-6,0,-5>, <-5,10,5>
  material{MRed}
}


box { // Right_Wall
  <5, 0, -5>, <6, 10, 5>
  material{MBlue}
}

box { // Back_Wall
  <-6, 0, 5>, <6, 10, 6>
  material{MWhite}
}


difference{
  box {<-6, 10, -5>, <6, 11, 6>}
  box {<-1.5, 9, -1.5>, <1.5,11, 1.5>}
  material{MWhite}
}

box { // Floor
  <-6, -1, -5>, <6, 0, 6>
  material{MWhite}
}