#include "glass.inc"

#declare S = seed(12345);

global_settings {
	ambient_light 0
	max_trace_level 100
	radiosity { count 100 error_bound 1.0 recursion_limit 5 }
	photons { count 1000000 }
}

camera {
	location <-0.06, 0.085, -0.14>*3
	look_at <0.01, 0.09, 0.05>
	sky <0.01, 1, 0>
	angle 25
	right image_width/image_height*x
	aperture 0.01
	blur_samples 100
	variance 1/10000
	focal_point <0, 0.0975, 0>
}

light_source {
	<10, 5, 0>, rgb <1,1,0.8>*5
	area_light x, y, 5, 5
	circular
	orient
	photons { area_light }
}

sky_sphere { pigment { rgb <0.9, 0.9, 1.0>*10 } }

union { // Huone
	box { // Lattia
		<-0.5, -0.1, -0.5>
		< 0.5,  0.0,  0.5>
		translate y*-0.5
	}
	box { // Katto
		<-0.6, -0.1, -0.6>
		< 0.6,  0.0,  0.5>
		translate y*1.1
	}
	box { // Etuseinä
		<-0.6, -0.1, -1.0>
		< 0.6,  0.0,  0.6>
		rotate x*90
		translate <0, 0, -0.5>
		//no_image
	}
	box { // Takaseinä
		<-0.5, -0.1, -1.0>
		< 0.5,  0.0,  0.6>
		rotate x*90
		translate <0, 0, 0.5>
		pigment { rgb 0.75 }
	}
	box { // Länsiseinä
		<-0.6, -0.1, -0.5>
		< 1.0,  0.0,  0.5>
		rotate z*90
		translate <-0.6, 0, 0>
	}
	difference {
		box { // Itäseinä
			<-0.6, -0.1, -0.5>
			< 1.0,  0.0,  0.5>
			rotate z*90
			translate <0.5, 0, 0>
		}
		box { <0.4, 0.05, -0.4>, <0.7, 0.8, 0.2> } // Ikkuna
	}
	pigment { rgb <0.75, 0.80, 0.65> }
	photons { collect off }
}

union { // Pöytä
	box {
		<-0.5, -0.03,  0.0>
		< 0.5,  0.0,  0.5>
	}
	difference {
		cylinder { <-0.5, -0.03, 0.0>, <0.5, -0.03, 0.0>, 0.03 scale <1, 1, 0.5> }
		plane { y, -0.03 }
	}
	pigment {
		average
		pigment_map {
			[granite
			color_map {
				[0.0 color rgb <0, 0, 0>]
				[0.4 color rgb <0, 0, 0>]
				[0.5 color rgb <0.5, 0.5, 0.5>]
				[1.0 color rgb <1, 0.73, 0.55>]
			}
			turbulence 0.1]
			[0.2 granite
			color_map {
				[0.0 color rgb 0]
				[1.0 color rgb 1]
			}
			turbulence 0.05
			scale 0.1]
		}
		scale 0.1
	}
	finish {
		specular 0.5
		reflection { 0.0, 0.75 fresnel }
	}
	interior { ior 1.5 }
}

union { // Puulevyt
	superellipsoid {
		<0.01, 0.1>
		scale <0.3, 0.3, 0.01>
		translate <-0.301, -0.33, 0>
	}
	superellipsoid {
		<0.01, 0.1>
		scale <0.3, 0.3, 0.01>
		translate <0.301, -0.33, 0>
	}
	pigment {
		wood
		color_map {
			[0.0 color rgb <0.6, 0.52, 0.3>]
			[0.7 color rgb <0.6, 0.52, 0.3>]
			[1.0 color rgb <0.55, 0.47, 0.25>]
		}
		scale 0.005 rotate <90, 0, 0>
		warp { repeat x*0.1 }
		warp { turbulence 0.05 }
	}
	normal { bumps 0.05 scale 0.001 }
	finish {
		specular 1.0
		roughness 0.1
	}
	interior { ior 1.1 }
	photons { collect off }
}

union { // Vesilasi
	merge { // Lasi
		difference {
			cone { <0, 0, 0>, 0.025, <0, 0.1, 0>, 0.030 }
			cone { <0, 0.015, 0>, 0.023, <0, 0.1001, 0>, 0.028 }
			sphere { <0, 0, 0>, 0.023 scale <1, 0.25, 1> translate y*0.015 }
		}
		torus { 0.029, 0.001 translate y*0.1 }

		pigment { Col_Glass_Clear }
		finish { F_Glass8 }
		interior { I_Glass1 }
		
		photons {
			target
			reflection on
			refraction on
		}
	}
	
	difference {
		intersection { // Vesi
			merge {
				cone { <0, 0.01, 0>, 0.023, <0, 0.1001, 0>, 0.028 }
				sphere { <0, 0, 0>, 0.023 scale <1, 0.25, 1> translate y*0.015 }
			}
			plane { y, 0.0875 }
			scale 0.9999
		}

		// Kuplat
		#declare MyCone = intersection {
			merge {
				cone { <0, 0.01, 0>, 0.023, <0, 0.1001, 0>, 0.028 }
				sphere { <0, 0, 0>, 0.023 scale <1, 0.25, 1> translate y*0.015 }
			}
			plane { y, 0.0875 }
			scale 0.9999
		}

		#declare S = seed(12345);
		#declare Norm = <0, 0, 0>;
		union {
			#declare Index = 0;
			#while (Index < 200)
				#declare Pos = trace(MyCone, <0,0.045,0>, <0.5-rand(S),0.5-rand(S),0.5-rand(S)>, Norm);
				#if (vlength(Norm) != 0)
					sphere { Pos-Norm*0.0005, 0.0005 }
				#end
				#declare Index = Index + 1;
			#end
		}
		
		pigment { rgb 1 filter 1 }
		finish { reflection { 0.0, 1.0 fresnel } }
		interior { ior 1.33 }
		
		photons {
			target
			reflection on
			refraction on
		}
	}

	translate <0.0, 0.0001, 0.05>
}

union { // Takalaatat
	#declare WallWidth = 10;
	#declare WallHeight = 11;
	#declare IndexX = 0;
	#while (IndexX < WallWidth)
		#declare IndexZ = 1;
		#while (IndexZ < WallHeight)
			superellipsoid {
				<0.5, 0.05>
				translate <IndexX*2.01, 0, IndexZ*2.01>
				scale <1.0, 0.01, 1.0>
				pigment { 
					agate
					color_map {
						[0.0 rgb 1]
						[0.9 rgb 1]
						[1.0 rgb 0.975]
					}
					agate_turb 0.5
					rotate x*180*rand(S)
				}
				finish {
					specular 0.75
					roughness 0.01
					reflection { 0.0, 0.5 fresnel }
				}
				normal { bumps 0.005 scale 0.1 }
				interior { ior 1.5 }
			}
			#declare IndexZ = IndexZ + 1;
		#end
		#declare IndexX = IndexX + 1;
	#end
	
	scale 0.1
	rotate x*-90
	translate <-1.2, -0.099, 0.4>
}