// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.5;

#include "colors.inc"
#include "functions.inc"
#include "rand.inc"

global_settings {
  assumed_gamma 1.0
  adc_bailout 1/24 // 0.0039
  // used in global_settings, sets the maximum ray tracing bounce depth (1 or more) [5]
  max_trace_level 32

}
                         
                         
// ----------------------------------------

camera {
  location  <0.0, 0.5, -4.0>
//  location  <-4.0, 3.5, -8.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 0.0,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

 light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <0.2, 0.22, 0.25>  // light's color
  translate <-30, 30, -30>  
  shadowless
  media_interaction off 
} 

// ----------------------------------------

#declare P_func=function(x,y,z) {
    f_bozo(x,y,z)
    }       
    
#declare F=function(x,y,z) {
    P_func(
            x/20,
            y*3-f_noise3d(x+y*0.2,0,0)*5,
            z*3-f_noise3d(x+z*0.2,0,0)*5
          )
    }                                   

#declare IsoMin=-x-2;
#declare IsoMax=x+2;
#declare Sd=seed(42);
    
#declare MyIso=isosurface {
    function{F(x/0.4,y*4,z*4)}
    max_gradient 45.0
    threshold 0.2
    contained_by {
        box { IsoMin IsoMax}
        }                         
    }          

#declare TestObj=
    intersection {
        union {
            #declare i=32;
            #while (i>0)   
            sphere {VRand_In_Box(IsoMin,IsoMax,Sd), rand(Sd)*0.7}   
            #declare i=i-1;                                          
            #end
            }                                                 
        box {
            IsoMin,
            IsoMax
            }
    }


#declare i=32;
#while(i>0)
    #declare P=VRand_In_Box(IsoMin,IsoMax,Sd);
    #if(!inside(MyIso,P))
        #declare i=i-1;
        light_source { P color rgb VRand_In_Box(<0,0,0>+0.5,<0.8,0.9,1>,Sd)*8 fade_power 2 fade_distance 0.1 media_attenuation on}
    #end
#end          

 object {
    MyIso
//    TestObj
    pigment { color rgb 1 }             
    finish { 
        ambient 0 
        diffuse 0.6
        brilliance 1.3 
        phong 1 
        phong_size 40 
//        reflection 0.3 
        }                     
    }                         
    
#declare media_box=box {
    IsoMin, IsoMax
    pigment { color rgbt <0,0,0,1> }
    finish {
        ambient 0
        diffuse 0
        phong 0
        specular 0
        reflection 0                
        }                   
    interior {  
        media {
            intervals 4           // number of intervals used for sampling [10]
            samples 1,1            // minimum and maximum number of samples taken per interval [1,1]
            confidence 0.8         // statistic parameter higher->better quality [0.9]
            variance 1.0/64       // statistic parameter lower->better quality [1.0/128]
            method 3               // adaptive sampling
            ratio 0.9              // distribution between lit and unlit areas [0.9]
            scattering {
                2 , 
                0.3     
                extinction 1
                }
            }           
        }       
    hollow 
    scale 1.1
    }      
    
// plane {y IsoMin.y*1.01pigment { checker color rgb 1 color rgb 0.8 }}    

object { media_box }