#version Unofficial MegaPov 0.7;

#declare Pig_crack=
   pigment{ 
    crackle 
    warp {
     turbulence 1/3
     octaves 4
     omega 2/3
     lambda 2.2
    }
    scale 1/5
    color_map {
     [0.01, color rgb 1]
     [0.03, color rgb 0]
    }
   }

#declare P_sph=function{"sphere",<1>}
#declare P_cracks=function{
 pigment{ 
  Pig_crack
 }
}

#declare P_noise=function{"heteromf",<0.5,1.7,4,0,0>}

#declare Planet_iso=function{P_sph(x,y,z)+2e-2*P_cracks(x+435,y+3345,z+267)-5e-3*max(0,P_noise(x*30,y*30,z*30))}

#declare Tex_Aussen=texture {
 pigment{color rgb 0.5}
 finish { phong 0.0 phong_size 0.1 brilliance 1.1 diffuse 0.3}
}                                 

#declare Tex_Innen=texture { 
 pigment{
  spherical
  color_map {
  [0,color rgb <1,0.1,0>*0.8]
  [0.1,color rgb <1,0.7,0.1>]
  }
 }
 finish {ambient 0.4 diffuse 1e-2}
}

#declare Planet_mat=
 material {
  texture {  
   spherical
   texture_map{
    [0.0, Tex_Aussen ]
    [0.01, Tex_Innen]
   }
  }                   
 }

#declare Planet=
isosurface{                
 function{ Planet_iso } 
 contained_by { sphere 0,2}
 threshold 0
 material { Planet_mat}
}               
//#declare Planet=sphere{0,1 material {Planet_mat}}

object{Planet}
/*
sphere {
 0,2
 texture{ pigment { color rgbt <1,0,0,0.8>}  finish {ambient 0.8 diffuse 0.2 brilliance 0.2} }
}
  */                     
light_source {
 <1,1e-4,1>*100000,color rgb <0.8,0.8,1>*5 rotate y*180
}                          

light_source {
 <1,-1,0>*100000,color rgb <1.0,0.3,0.2>*1 rotate x*20
}                          


camera {
 right x
 up y
 location <1,1,0>*1.9
 look_at 0           
// angle 160
}
 
sky_sphere{
 pigment{
  granite
  color_map{
   [1/25, color rgb 1]
   [1/25, color rgbt 1]
  }    
  scale 1/10
 }
/* Sonne
 pigment {
  average
  pigment_map {
#declare _rs=seed(64356);
#local _a=0;
 #while (_a<360)  
  [ 1
   spherical
   color_map {
    [0 color rgbt <1,1,1,1>]
    [1 color rgbt <1,1,1,-0.3>]
   }                           
   #local _sc_l=rand(_rs);
   scale <1/(rand(_rs)*50+1),1+_sc_l,1+_sc_l>
   
   rotate z*_a
   translate -z
   rotate y*90
   rotate z*25
   rotate y*25
  ]
  #local _a=_a+3;
 #end  
  }
 }
 */
}