#version unofficial MegaPov 0.7;	//remove this line when using POV3.5
#default {pigment{rgb <0,0,.3> transmit 0} finish {ambient 1}}
#declare Resx=800;
#declare Resy=600;
camera {
	orthographic
	location <.5,50,.5>*<Resx,1,Resy>
	right x*Resx
	up y*Resy
	look_at <.5,0,.5>*<Resx,1,Resy>
}
#declare photo=
height_field {
	png "photo.png"
	smooth
	scale <1,-1,1>
	translate y
	scale <Resx,1,Resy>
}

#declare AantalX=300;		//horizontal sample-resolution
#declare AantalY=200;		//vertical sample-resolution
#declare Seed=seed(567);	//seed-value for randomness in direction of pen-strokes
#declare randomX=0;			//amount of jitter in horizontal sample-placing
#declare randomY=0;			//amount of jitter in vertical sample-placing

#declare TelX=0;
#declare Res=(Resx+Resy)/4;
#while (TelX<AantalX)
	#declare TelY=0;
	#while (TelY<AantalY)
		#declare N=<0,0,0>;
		#declare P=<TelX/AantalX,5,TelY/AantalY>*<Resx,1,Resy>+<rand(Seed),0,rand(Seed)>*<randomX,1,randomY>-<randomX/2,0,randomY/2>;
		#declare snijpunt=trace(foto,P,-y,N);
		
		#declare Norm=vnormalize(<N.x,0,N.z>);
		#declare L=abs(N.y)*.9+.1;
		#declare Lengte=((snijpunt.y*.5+.5)*(Res/20)+.02)*L/1;
		#declare Breedte=(pow(snijpunt.y*.99+.01,1.5)*(Res/20)+.01)/50;
		#if (Norm.x!=0 | Norm.z!=0)
			cylinder {
				-Norm*Lengte,Norm*Lengte,Breedte
				rotate y*(85+10*rand(Seed))
				translate P*<1,.1,1>
			}
		#else
			#declare Norm=vrotate(<1,0,0>,y*360*rand(Seed));
			#declare Lengte=Lengte/2;
			cylinder {
				-Norm*Lengte,Norm*Lengte,Breedte
				translate P*<1,.1,1>
			}
		#end
		#declare TelY=TelY+1;
	#end
	#declare TelX=TelX+1;
#end

background {rgb 1}