// Persistence of Vision Ray Tracer Scene Description File
// File: Rad_test2.pov
// Vers: 3.5
// Desc: Radiosity Test
// Date: 14/09/2001
// Auth: Andy Cocker
//
#include "colors.inc"
#include "textures.inc" 
#include "stones1.inc"
#include "woods.inc"
#include "golds.inc"

#version 3.5;

global_settings {
photons { spacing 0.02  autostop 0 } // Don't think these show up.
  assumed_gamma 1.0
  
  radiosity {
      pretrace_start 0.08           // start pretrace at this size
      pretrace_end   0.02           // end pretrace at this size
      count 75                      // higher -> higher quality (1..1600) [35]
      nearest_count 10               // higher -> higher quality (1..10) [5]
      error_bound 0.25               // higher -> smoother, less accurate [1.8]
      recursion_limit 1             // how much interreflections are calculated (1..5+) [3]
      low_error_factor .2           // reduce error_bound during last pretrace step
      gray_threshold 0.0            // increase for weakening colors (0..1) [0]
      minimum_reuse 0.015           // reuse of old radiosity samples [0.015]
      brightness 1                  // brightness of radiosity effects (0..1) [1]

      adc_bailout 0.01/2
      
    }
  
}


// ----------------------------------------

#declare Cam_Look_At=<-4,0,0>;
#declare Cam_Loc=<0,8,-8>; 

camera { 
  right x*image_width/image_height
  location  Cam_Loc
  look_at   Cam_Look_At
  angle 55

}

light_source {
  <-18,25,0>       
  color rgb <1, 1, 1>  
photons {reflection on refraction on}
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0 rgb 1]
      //[0.7 rgb <0.0,0.1,0.8>]
    }
  }
}



//-----------
#declare MyWood1 =
    texture { pigment { P_WoodGrain19A color_map { M_Wood7A }}}
    texture { pigment { P_WoodGrain19B color_map { M_Wood7B }}}
   
union {
difference {
        cylinder {<0,-5.51,0>,<0,10,0>,10}
        cylinder {<0,-5.5,0>,<0,11,0>,9.5}
}
difference {
        cylinder {<0,2,0>,<0,2.5,0>,10}
        cylinder {<0,1.9,0>,<0,2.6,0>,6}
} 
difference {
        cylinder {<0,-0.5,0>,<0,0,0>,10}
        cylinder {<0,-0.6,0>,<0,0.1,0>,3 scale <0.75,1,1.3>}
        cylinder {<0,-0.6,0>,<0,0.1,0>,3 scale <1.3,1,0.75>}
}
difference {
        cylinder {<0,-3.5,0>,<0,-3,0>,10}
        cylinder {<0,-3.51,0>,<0,-2.9,0>,1}
}        
               
texture {MyWood1 finish {ambient 0}}
}

#declare RR=seed(1734);

union { 
#declare Count=1;
#while (Count<=20)
sphere {<0,1,0>,1 texture {DMFDarkOak scale .2 finish {ambient 0}
        rotate <rand(RR)*360,rand(RR)*360,rand(RR)*360>}//end texture 
        translate <0,0,7> rotate <0,Count*18,0>
        }
#declare Count=Count+1;
#end

} 

union { 
#declare Count=1;
#while (Count<=20)
sphere {<0,1,0>,1 
        translate <0,2.5,7.5> rotate <0,Count*18,0> 
        texture {T_Grnt25 finish {ambient 0}}}
#declare Count=Count+1;
#end

} 

/*
union { 
#declare Count=1;
#while (Count<=10)
sphere {<0,1,0>,1 
        translate <0,0,4.5> rotate <0,Count*36,0>}
#declare Count=Count+1;
#end
material {My_Glass}
photons {target 1 reflection on refraction on collect off}}
//------------
*/
        
union { 
#declare Count=1;
#while (Count<=6)
sphere {<0,0,0>,1 scale <0.45+((rand(RR)+0.001)/2),1,0.45+((rand(RR)+0.001)/2)>
        translate <0,-2,2> rotate <0,Count*60,0>}
#declare Count=Count+1;
#end
texture {T_Gold_3C finish {ambient 0}}
photons {target 1 reflection on refraction on }}

union { 
#declare Count=1;
#while (Count<=15)
sphere {<0,1,0>,1 
        translate <0,-3,5> rotate <0,Count*24,0>}
#declare Count=Count+1;
#end
texture {T_Grnt18 finish {ambient 0}}
}

sphere {<0,-4.5,0>,1 texture {T_Grnt13 finish {ambient 0}}}