/*sun-a-rise*/

#version Unofficial Megapov 0.7;

#declare fEarthRad = 600000;
#declare fDensityFactor = 50;
#declare fSkyHeight = 1000;

#declare _clock = clock;
//#declare _clock = 1;

#declare light_loc = <0,10*fEarthRad*sin(pi*_clock)-fEarthRad,10*fEarthRad*cos(pi*_clock)>;

global_settings {
	assumed_gamma 1.0
	ini_option "+QR" 
	radiosity
	{
		media on
	}
	max_trace_level 20
}

#declare bmod = 1.3;

camera {
	right			x*image_width/image_height
	up				y
	direction	z
	
	location <100,0,0>
	look_at <0,0,250>
}


light_source {
	light_loc
	rgb bmod
}

glow {
	type 1
	location light_loc
	size fEarthRad/10
	fade_power 2
	colour rgb bmod
}


sphere {
	<0,0,250>, 50
	texture {
		pigment { rgb 1 }
		finish {
			diffuse 1/bmod
			ambient 0
		}
	}
}



//the ground and sky

union {
	sphere {
		<0,0,0>, fEarthRad
		texture {
			pigment { rgb 1 }
			finish {
				diffuse 1/bmod
				ambient 0
			}
		}
	}
	sphere {
		<0,0,0>, fEarthRad+fSkyHeight
		hollow on
		material {
			texture {
				pigment {
					rgbt <1,1,1,1>
				}
				finish {
					ambient 0
					diffuse 1/bmod
				}
			}
			interior {
				media {
					
					scattering {
						0, rgb <0.1,0.3,1>
						extinction 1
					}
				
				  intervals 4//20
				  samples 1, 8//20
				  confidence 0.99
				  variance 1.0/256.0
				  
				  density {
				  	spherical
				  	density_map {
				  		[0 rgb 0.00000]
				  		[(fSkyHeight/(fEarthRad+fSkyHeight))
				  			rgb 0.00001*fDensityFactor]
				  	}
				  	scale fEarthRad+fSkyHeight
				  }
				}
			}
		}
	}

	translate <0,-fEarthRad,0>
	translate <0,-50,0>
}