// ClothRay example: nappe.pov
// Christophe Bouffartigue (tofbouf@free.fr)

#version unofficial MegaPov 0.7;

#macro WriteClothFile(nomfile, n1, n2, nlng, ks, ht)

	#debug "\nWriting new .cth file\n"
	#fopen file nomfile write
	#write(file, n1, ",", n2, ",", nlng, ",", ks, ",\n")
	
	#local l1 = nlng*(n1-1);
	#local l2 = nlng*(n2-1);
	#local st = seed(1234);
	#local i=0;
	#while (i<n1)
		#local j=0;
		#while (j<n2)
			#local tempx = -l1/2 + i*nlng;
			#local tempz = -l2/2 + j*nlng;
            #local tempy = ht + (-1+2*rand(st))*nlng*0.1;
			#write(file, tempx, ",", tempy, ",", tempz, ", 0.0, 0.0, 0.0,\n")
			#local j=j+1;
		#end
		#local i=i+1;
	#end
	#fclose file
#end


#declare Table = union {
	cylinder { .8*y, .9*y, .8 }
	torus { .8, .05 sturm translate .85*y }
	cylinder { .85*y, 0, .05 }
	cylinder { 0, .05*y, .4 }
}

WriteClothFile("nappe.cth", 60, 60, 1.85/60, 30, .95)

simcloth {
	environment Table
	friction 0
	gravity -.4*y
	damping .90
	intervals .03
	iterations 200
	input "nappe.cth"
	output "nappe.cth"
	mesh_output "nappe.msh"
	smooth_mesh on
	uv_mesh on
}

#declare Nappe = mesh {
	#include "nappe.msh"
	uv_mapping
	texture { pigment { checker color rgb<1, .5, .2> color rgb<1, .8 ,.4> scale <1/10, 1/10, 1/10>} }
}

camera {location -2*z+1.2*y+.2*x look_at .5*y }
light_source { -2*z+0.5*y-.2*x, color rgb .5 shadowless }

light_source { <1,2,-1>*3, color rgb 1.2
	spotlight
	radius 20
	falloff 30
	tightness 2
	point_at 0
}


object { Nappe translate .001*y }
object { Table scale <.98, 1, .98>
	pigment { rgb <.8, .5, .1> }
}

// floor
plane { y, 0
	pigment { color rgb .8 }
	finish { ambient .3 diffuse .7 }
}

// walls
plane { x, -3
	pigment { color rgb .8 }
	finish { ambient .3 diffuse .7 }
}
plane { -z, -3
	pigment { color rgb .8 }
	finish { ambient .3 diffuse .7 }
}