#include "colors.inc"

background{Blue}

camera{location<0,0,-10> look_at<0,0,0> angle 15 rotate y*0}

light_source{<5,5,-20> color White fade_distance 40 fade_power 2}
//light_source{<10,5,-30> color White shadowless}

//sphere{<0,0,0> .5 pigment{rgbf<0,1,0,.9>}}

#declare mouthWidth=1.75;
#declare mouthHeight=.5;
#declare mouthXRotate=-45;
#declare mouthYRotate=0;
#declare mouthOffset=<0,-.35,-.35>+<0,.028,-.05>;

// mouthStrength
// negative gives a hole
// positive gives a bump
// Zero gives nothing
#declare mouthStrength=-1;

//modify height of eye orbit holes
#declare rorbitOpen=1.25;
#declare lorbitOpen=1.25;

//modify angle of eyelid opening
#declare rlidOpen=20;
#declare llidOpen=20;

//rotate eyes left to right
#declare reyeYrotate=-10;
#declare leyeYrotate=-35;

//rotate eyes Up and Down
#declare reyeXrotate=0;
#declare leyeXrotate=0;

//declare head object
#declare head=blob{ threshold .5
   //head
   cylinder{<0,-.5,0><0,1,0>,.55,10
      scale<1,.6,1>
      matrix<1,0,0,
             0,1,0,
             0,.4,1,
             0,0,0>}
             
   //chin
   sphere{<0,0,0>.3, 2 scale<1.2,.6,.5> rotate x*-45 translate<0,-.6,-.35>}
   //nose
   sphere{<0,0,0>.15,10 scale<.75,1,1.5> rotate x*-45 translate<0,-.05,-.5>}
   sphere{<0,0,0>.1,5 translate<.09,-.1,-.5>}   //nostril 
   sphere{<0,0,0>.05,-6 translate<.1,-.15,-.5> pigment{Black * 20}}   //nostril hole
   sphere{<0,0,0>.1,5 translate<-.09,-.1,-.5> }  //nostril
   sphere{<0,0,0>.05,-6 translate<-.1,-.15,-.5> pigment{Black * 20}}   //nostril hole
   //cheek 
   cylinder{<-.3,0,0><.3,0,0>.25,5 scale<1,1,.8> rotate x*-20
      translate<0,-.12,-.25>}
   //mouth cavity
   sphere{<0,0,0>.2,-20 scale<1,2,1> translate<0,-.3,-.27> pigment{Red*.5}}
   
   //mouth hole
   sphere{<0,0,0>.15,1.5 * mouthStrength
      scale<mouthWidth,mouthHeight,1>
      rotate x * mouthXRotate
      rotate y * mouthYRotate
      translate mouthOffset
      pigment{Red*.5}}
      
   //eye socket
   sphere{<0,0,0>.175,-1.5 scale<1.25,rorbitOpen,.75> translate<0,.2,-.4> rotate y*-27}
   sphere{<0,0,0>.175,-1.5 scale<1.25,lorbitOpen,.75> translate<0,.2,-.4> rotate y*27}
   
   //head color and texture
   texture{
      normal{bumps .05 scale .01}
      pigment{Flesh}
      }
}//end blob

#declare eye=sphere{<0,0,0>.15
   pigment{
      gradient z scale .2
      pigment_map{
         [0 White]
         [.65 White]
         [.65 Blue *.25]
         [.725 Blue]
         [.725 Black]
         [1 Black]
         }
      }
   finish{phong 2}      
   }

#declare teeth=difference{
   cylinder{<0,0,0><0,.2,0> .25 scale<1,.5,1>}
   cylinder{<0,-.1,0><0,.3,0> .25 scale<2,.5,1> translate<0,0,.1>}
   pigment{White}
   }

#declare eye_lid=difference{
   sphere{<0,0,0>.16}   
   sphere{<0,0,0>.15}
   box{<-1,0,-1><1,-1,1>}
   pigment{Flesh}
   }
   
difference{
   object{head}
   //box{<0,-2,-2><2,2,2>}
   }

object{eye rotate x * reyeXrotate rotate y * reyeYrotate translate<-.19,.2,-.31>}
object{eye_lid
   rotate x * rlidOpen
   rotate x * reyeXrotate
   rotate y * reyeYrotate
   translate<-.19,.2,-.31>}
object{eye_lid
   rotate x * rlidOpen
   scale<1,-1,1>
   rotate x * reyeXrotate
   rotate y * reyeYrotate
   translate<-.19,.2,-.31>}
object{eye rotate x * leyeXrotate rotate y * leyeYrotate  translate<.19,.2,-.31>}
object{eye_lid
   rotate x * llidOpen
   rotate x * leyeXrotate
   rotate y * leyeYrotate
   translate<.19,.2,-.31>}
object{eye_lid
   rotate x * llidOpen
   scale<1,-1,1>
   rotate x * leyeXrotate
   rotate y * leyeYrotate
   translate<.19,.2,-.31>}
object{teeth rotate x*0 translate<0,-.36,-.2>}

//hair
blob{
   sphere{<0,0,0>.5,10 scale<1,1,1.5>}
   sphere{<0,-.1,-.4>.25,-4}
   scale<1,.75,1>
   translate<.25,.7,0>
   pigment{Yellow}
   }
blob{
   sphere{<0,0,0>.5,10 scale<1,1,1.5>}
   sphere{<0,-.1,-.4>.25,-4}
   scale<-1,.75,1>
   translate<-.25,.7,0>
   pigment{Yellow}
   }