// Persistence of Vision Ray Tracer Scene Description File
// File: sunset.pov
// Vers: MegaPOV 0.6a
// Desc: First attempt at a 'realistic' scene.
// Date: 4 January 2001
// Auth: Alan Holding - manhog@lineone.net

//  Set-ups
#version unofficial MegaPOV 0.6;
global_settings {assumed_gamma 1.8}
background {rgb <0.2,0.2,0.4>}

//  Atmospherics.
//  The sky is made up of two rescaled hollow spheres.
//  One is inside the other, but both enclose the heightfield.
fog {fog_type 1 rgb <0.4,0.4,0.8> distance 1000}

sphere {
  y 2002
  pigment {
    wrinkles
    colour_map {
      [0.0 rgbf <1,1,1,1>]
      [0.4 rgbf <1,1,1,1>]
      [0.5 rgbf <1,1,1,0.6>]
      [0.6 rgbf <1,1,1,0.2>]
      [1.0 rgbf <1,1,1,0>]
    }
    turbulence 0.05
    scale 500
  }
  finish {ambient 0 diffuse 0.25}
  hollow on
  scale <1,0.25,1>
}

sphere {
  y 1502
  pigment {
    wrinkles
    colour_map {
      [0.0 rgbf <1,1,1,1>]
      [0.4 rgbf <1,1,1,1>]
      [0.5 rgbf <1,1,1,0.6>]
      [0.6 rgbf <1,1,1,0.2>]
      [1.0 rgbf <1,1,1,0>]
    }
    turbulence 0.15
    scale 500
  }
  finish {ambient 0 diffuse 1}
  hollow on
  no_shadow
  scale <1,0.25,1>
}

//  Camera
//  I usually render my images in Cinemascope, a ratio of 2.35:1.
//  Render this as 800 width, 340 height to see what I mean.
camera {
  location <800,55,-900>
  right x*image_width up y*image_height
  angle 65
  look_at <5,-30,-10>
  perspective
}

//  Lights
#declare sun_pos=<-50,150,2700>;
//  focus_pos was where my robot stood in the image posted to povray.binaries.images.
//  I'll get round to finishing him someday...
#local focus_pos=<530,30.25,-800>;

light_source {sun_pos rgb <2,1.25,0.5> glow {type 0 size 75 radius 4000 fade_power 2}}
glow {type 0 location sun_pos color rgb <1,1,0> size 100 radius 1000 fade_power 2}
light_source {sun_pos rgb <1,0.9,0.7>*200 spotlight point_at focus_pos radius 50 falloff 300 tightness 1}
light_source {<500,100,0>*3 rgb 0.2 shadowless}

//  Texture for the heightfield - code would get very messy otherwise!
//  PLEASE NOTE:  The colours in the colour_map were stolen from Ken Tyler's
//  kolors.inc include file.  They are known in that file as Goldenrod1 -> 4.
//  Put them here as rbg vectors as not sure if *you've* got kolors.inc. 8O)
#local txt_landscape=texture {
  pigment {
    bozo
    colour_map {
      [0.0 rgb <0.8516, 0.6445, 0.1250>]
      [0.2 rgb <0.9297, 0.7031, 0.1367>]
      [0.3 rgb <1.0000, 0.7539, 0.1445>]
      [0.8 rgb <0.8008, 0.6055, 0.1133>]
      [1.0 rgb <0.8516, 0.6445, 0.1250>]
    }
    turbulence 0.01
    scale 50
  }
  normal {granite 0.75 scale 25 turbulence 0.05}
}

//  Heightfield
//  Change size_of_pattern for more detailed heightfield:
//  200 is quick but rough, 5000 is slow but nice.
#local size_of_pattern=500;
#local hf_scale=0.5;
#local seeder=seed(2058);
#local looper=0;
#local no_of_interpolations=30;

#local quick_hf=height_field {
  pattern size_of_pattern,size_of_pattern {
    hf_gray_16
    wrinkles
    colour_map {
      #while (looper<no_of_interpolations)
        [looper/no_of_interpolations rgb ((rand(seeder)+rand(seeder))/2+sin(rand(seeder)/2)/2)]
        #local looper=looper+1;
      #end
    }
    scale hf_scale
  }
  texture {txt_landscape}
  translate <-0.5,0,-0.5>
  scale <2000,35,2000>
}

//  Action!
#version 3.1;
object {quick_hf}

//  End of scene file.