#version unofficial MegaPov 0.6;
                      
global_settings {
        max_trace_level 32 
        assumed_gamma 3
        motion_blur 25,0.1
        radiosity {
                brightness 1.2
                count 8
                recursion_limit 4
                }                
        }        

                      
#declare tau=(sqrt(5)-1)/2;
#declare pointlist=array[12] {
                        <0,1,tau>,
                        <0,1,-tau>,
                        <1,tau,0>,
                        <1,-tau,0>,
                        <0,-1,-tau>,
                        <0,-1,tau>,
                        <tau,0,1>,
                        <-tau,0,1>,
                        <tau,0,-1>,
                        <-tau,0,-1>,
                        <-1,tau,0>,
                        <-1,-tau,0>                        
                        }  

#declare facelist=array[20][3]{ 
                                {0,2,6},
                                {6,3,4},
                                {6,3,5},
                                {7,6,5},
                                {7,0,6},
                                {2,8,3},
                                {1,8,2},
                                {0,1,2},
                                {10,1,0},
                                {10,9,1},
                                {1,9,8},
                                {3,8,4},
                                {5,3,4},
                                {11,5,4},
                                {11,10,7},
                                {7,10,0},
                                {9,11,4},
                                {9,4,8},
                                {11,7,5},
                                {11,9,10}
                               }
motion_blur {                               
        mesh {
                #declare i=20;
                #while (i>0) 
                #declare i=i-1;
                #declare p1=pointlist[facelist[i][0]];
                #declare p2=pointlist[facelist[i][1]];
                #declare p3=pointlist[facelist[i][2]];
                triangle {p1,p2,p3}
                #end  
                
                pigment {color rgbt <0.8,0.85,0.9,0.6>}
                finish {reflection 0.7 brilliance 3}
                }
        rotate <10*clock,20*clock,30*clock>    
        translate y
        }
#declare i=12;
#while (i>0)
#declare i=i-1;
        glow { 
                location pointlist[i]+y
                type 1
                size 0.0001
                color <1,0.6,0.5>
                } 
        
#end                                                                     
        
camera {
        location <1,2,-3>
        look_at <0,1,0>
        angle 55
        }                  
plane {  
        y
        0
        pigment {checker color rgb 0, color rgb 1}
        finish {reflection 0.4} 
              
        }                                          
        
light_source {
         <0,10,-15>
         color <1.0,0.98,0.9>
         }