#version unofficial MegaPov 0.6;
#include "blitz.pov"             

// Demofile for lighnings and a test of my multiplane-clouds ...

camera { 
        location <0,10,0>        
        look_at  <0,10,20>
        angle 90
        }            
        
/*camera { 
        location <0,1000,0>        
        look_at  <0,10,20>
        angle 120
        }      */
global_settings {
        max_trace_level 32 
        assumed_gamma 4.5
        radiosity {
                brightness 1.2
                count 8
                recursion_limit 4
                }                
        }        
           
#declare SunAlt=60;  //Height of Sun in Degrees
#declare SunPos=10;  //Pos of Sun in Degrees (Rotation around Y-Axis)
#declare LightDist=10000; // Distance of The Lightsources from <0,0,0> (its not wrong to make it big)
#declare Sunlight_Interference=1; // Spreading of the RGB-Channels ...

#declare LightSpread=LightDist/1000*Sunlight_Interference;
#declare LightPos= vrotate(<0,LightDist,0>,(90-SunAlt)*x+SunPos*y);
#declare sd=seed(42);

light_source { LightPos+<LightSpread,0,LightSpread>
	color <2.0,0.1,0.1>
}
light_source {
        LightPos+<-LightSpread,LightSpread,0>
 	color <0.1,2.0,0.1>
}
light_source {
        LightPos+<0,LightSpread,-LightSpread>
 	color <0.1,0.1,2.0>
}

                           
sky_sphere {
        pigment {
                gradient y
                color_map {
                        [ 0.0     rgbft <0.854133, 0.908804, 1.0, 0.0, 0.0> ]
                        [ 1.0     rgbft <0.729133, 0.824724, 1.0, 0.0, 0.0> ]
                        }
	        }
        pigment {
                wood
                color_map {
                        [ 0.00    rgbft <1.0, 1.0, 1.00, 0.0, 0.0> ] // Line used to create a Spot and align he Sun-Cenbter
                        [ 0.01    rgbft <1.0, 1.0, 1.00, 0.0, 0.0> ]
                        [ 0.1    rgbft <1.0, 1.0, 0.98, 0.0, 0.0> ]
                        [ 0.3    rgbft <0.7708, 0.918817, 1.0, 0.0, 0.864567> ]
                        [ 1.00    rgbft <0.7708, 0.918817, 1.0, 0.0, 1.0> ]
                        }
                scale  <2, 2, 1>
                rotate (-SunAlt)*x + SunPos*y 
                }   
        }

fog {
	fog_type 2
	distance 70
	color rgb <0.96,0.98,1.0>*0.2
	fog_offset 0
	fog_alt 4
}    
fog {
	fog_type 1
	distance 350
	color rgb <0.92,0.96,1.0>*0.55
	fog_offset 0
	fog_alt 2
}    
union {
        sphere { // ground
	        0,1000
                }        
        #declare I=100;
        #while (I>0)    
                #declare I=I-1;
                #declare p=<sin((I-50)/50)*1000,0,cos((I-50)/50)*1000>;
                sphere {p,50
                        pigment {  
                                gradient y 
                                color_map {
                                        [0.0 rgb <0.3, 0.4, 0.2>]
                                        [0.2 rgb <0.3, 0.4, 0.2>]
                                        [0.4 rgb <1.0, 1.0, 1.0>]
                                        [1.0 rgb <1.0, 1.0, 1.0>]
                                        }  
                                scale <1,50,1>
                                }      
                        scale <0.5,130*rand(sd)+100,0.5>
                        translate y*(rand(sd)*20-10)
                        }  

                
        #end                
	texture {
                pigment {color rgb <0.3, 0.4, 0.2> }
                finish {
                        ambient 0.25
                        diffuse 0.75
                        }                
                }
        scale <1,0.008,1>        
        translate <0,-8,0>
        }
         
#declare I=5;  // Number of Cloud-Layers (more -> darker)
union {
#while (I>0)                               
#declare I=I-1;
sphere {             //clouds ...
	0,2000+I*5
        scale <2,0.04,2>        
        translate <0,-20,0>
        hollow
        }
#end
        texture {      
                pigment {
                        bozo
                        color_map {
                                [ 0.00     rgbft <1.00, 1.00, 1.00, 0.00, 1.0> ]
                                [ 0.60     rgbft <1.00, 1.00, 1.00, 0.00, 1.0> ]
                                [ 0.65     rgbft <1.00, 1.00, 1.00, 0.01, 1.0> ]
                                [ 0.70     rgbft <0.90, 0.95, 1.00, 0.02, 0.96> ]
                                [ 1.00     rgbft <1.00, 0.97, 1.00, 0.01, 0.95> ]
                                }
                        turbulence <0.7, 0.7, 0.7>
                        ramp_wave
                        scale  100
                        }
                 finish {
                        ambient rgb <0.65, 0.60, 0.70>*0.3
                        }
                }
        }        //union



sphere {<0,0,45> 10 pigment{rgb 0} finish{reflection 1} scale <1,0.4,1> translate <0,0.2,0>} // to see something

$i=10; // Number of Lightnings ..
#while (i>0)   
$i=i-1;
$sp=<-50,80,100>+(<rand(sd)*2,rand(sd)*0.02,rand(sd)>*2-<1,0.01,0.5>)*80;
//blitz(org,start,dir ,lowpt  ,turb,branch_prob,branch_try,maxiter,dpth,lastpt) 
  blitz(sp, sp   ,3*-y,sp-sp.y,0.6   ,0.1       ,1          ,50     ,0    ,sp)
#end