#version unofficial MegaPov 0.6; 
//Radphotblur by Andy Cocker
// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "metals.inc"

#declare Shapes_On=yes;
#declare Rad_On=yes;
#declare Photons_On=no;
#declare Area_Light=yes;
#declare Reflect_Blur=yes;

#declare BlurSamps=20;

global_settings { 
#if (Photons_On) photons { spacing 0.02 gather 60, 100 autostop 0 jitter 1 } #end
max_trace_level 25
#if (Rad_On) ini_option "+QR" #end
radiosity {
	pretrace_start 0.16
	pretrace_end 0.08
    count 50             
    nearest_count 3      
    error_bound 2.5      
    recursion_limit 4    
    low_error_factor .5  
    gray_threshold 0.0   
    minimum_reuse 0.015  
    brightness 1         
    adc_bailout 0.01/(18*2)  
  }

}

camera{
  location <-7,4.5,-8>
  look_at <0,0.5,0>
  angle 45
} 

#if (Area_Light)
light_source
{
  0*x 
  color rgb 1.0  
  area_light
  <1, 0, 0> <0, 0, 1> 
  4, 4                
  adaptive 1
  orient 
  photons {area_light}         
//  jitter              
  translate <0, 5.5, 0>
  }
#else
light_source
{
  0*x 
  color red 1.0  green 1.0  blue 1.0  
  translate <0, 5.5, 0>
}
#end  


#declare MyHexDark=
material {
//1
texture {
pigment { hexagon color rgb .5,color rgb .4,color .3}
finish { specular .1 roughness 0.01 ambient 0 diffuse .8}
}
//2
texture {
pigment { hexagon color rgbf 1,color rgb <.4,.35,.35>,color  rgbf 1}
finish { specular .1 roughness 0.01 ambient 0 diffuse .8}
scale .25}
//3
texture {
pigment { hexagon color rgbf 1,color rgbf <.45,.45,.55,.8>, color rgbf 1}
finish { specular .1 roughness 0.01 ambient 0 diffuse .8}
scale .5}
//
texture {
pigment { hexagon color rgbf 1,color rgbf <.35,.25,.15,.55>, color rgbf 1}
finish { specular .1 roughness 0.01 ambient 0 diffuse .8}
scale .75}
}

#declare Glass = 
   material  {		
      texture {      
         pigment {
            color rgbf <1.0, 1.0, 1.0, 0.7>
         }      
         finish {
            ambient 0.0
            diffuse 0.0
            specular 1.0
            roughness 0.001
            reflection 0.5
         }
      }   
      interior { ior 1.2 }
   }


#declare MyChrome=
material {
texture {T_Chrome_3C
finish { reflection .9 reflect_metallic #if (Reflect_Blur) reflection_blur 0.015 reflection_samples BlurSamps #end}
}
} 

#declare MyGold=
material {
texture {T_Gold_3C
finish { reflection .9 reflect_metallic #if (Reflect_Blur) reflection_blur 0.015 reflection_samples BlurSamps #end}
}
} 

#declare MyDull=
material {
texture {
pigment { rgb 0}
finish { ambient 0 diffuse 1}
}
}



#declare seeed=seed(7);
#declare s1=seed(746);
#declare s2=seed(42242);
#declare choose=seed(89);

#if (Shapes_On) 
union {
#declare ex_direct=-8;
#while (ex_direct<=8)
#declare zed_direct=-8;
#while (zed_direct<=8)
union { 
#if (rand (choose)>0.5)//choose whether glass or gold
cylinder {<0,0.11001,0>, <0,0.5,0>,0.5 material {MyGold}}
#else
cylinder {<0,0.11001,0>, <0,0.5,0>,0.5 material {Glass}}
#end
cylinder {<0,0.05,0>,<0,0.11,0>,0.5 material {MyDull}}
cylinder {<0,-0.05,0>,<0,0.05,0>,0.5 texture {T_Gold_3C pigment {rgb <rand(seeed),rand(s1),rand(s2)>} 
        finish {reflection .9 reflect_metallic 
        #if (Reflect_Blur) reflection_blur 0.015 reflection_samples BlurSamps #end}
        }}
cylinder {<0,-0.11,0>,<0,-0.05,0>,0.5 material {MyDull}}
cylinder {<0,-.5,0>, <0,-0.11001,0>,0.5 material {MyChrome}} 
 rotate <rand(seeed)*360,rand(seeed)*360,rand(seeed)*360>
        translate <ex_direct,0,zed_direct>}
#declare zed_direct=zed_direct+2;
#end
#declare ex_direct=ex_direct+2;
#end

photons { target reflection on refraction on ignore_photons}
}                    
#end                    


union {
plane {y,0 material {MyHexDark scale .25 } rotate z*-90 translate x*-9 hollow}//left wall 
plane {y,0 material {MyHexDark scale .25 } rotate x*-90 rotate y*90 translate x*9 hollow}//right wall
plane {y,0 material {MyHexDark scale .25 } rotate x*-90 translate z*9 hollow}//back wall
plane {y,0 material {MyHexDark scale .25 } rotate x*90 translate z*-9 hollow}//near wall  
plane {y,0 material {MyHexDark scale .25 } rotate x*180 translate y*6 hollow}//top wall
plane {y,-0.7 material {MyHexDark scale .25 }hollow} //floor
}