//	Brick wall macro display file
//	Written by Mark Slone - slone@hiwaay.net - July 2002
//	POV-Ray 3.5 Settings

global_settings { assumed_gamma 1.0
        		  ambient_light rgb <0.1, 0.1, 0.1>
				  noise_generator 1  //  Old darker streaks (created using POV-Ray 3.1)
                 }

#include "BrickWall.mcr"
#include "VeniceLamp.inc"

//	Rotate wall and parts for good view

#declare WallRot = -45;

//	Stone

#declare Mottled_pigment =

pigment {
    bozo
    turbulence 0.60
    omega 0.80
    lambda 3.00
    color_map {
      [0.00 color rgb <0.6, 0.6, 0.6>]
      [1.00 color rgb <1.0, 1.0, 1.0>]
    		}
  	 }

#declare Granite_streaks =

texture {
  pigment {
        granite
        color_map {
                [0.0 rgbt <0.65, 0.65, 0.65, 1.0>]
                [0.1 rgbt <0.65, 0.65, 0.65, 1.0>]  //  0.4 rgbt = fewer streaks
                [1.0 rgbt <0.10, 0.10, 0.10, 0.2>]
                   }
        scale <2.0, 5., 2.0>
           }
	}

#declare MottledMarble_texture =

texture { pigment { Mottled_pigment } }
texture { Granite_streaks }

//	Water streaks

//	Dark water streaks
//	To make darker, change rgb darker or t less transparent

#declare Streaky =

  pigment {
      bozo
    color_map {
      [0.00 color rgbt <0.18, 0.10, 0.05, 0.9>]  
      [0.10 color rgbt <0.18, 0.10, 0.05, 0.3>] 
      [0.25 color rgbt <0.18, 0.10, 0.05, 0.9>]
      [0.37 color rgbt <0.18, 0.10, 0.05, 0.3>]  
      [0.63 color rgbt <0.18, 0.10, 0.05, 0.9>]  
      [0.75 color rgbt <0.18, 0.10, 0.05, 0.3>]  
      [0.90 color rgbt <0.18, 0.10, 0.05, 0.9>] 
      [1.00 color rgbt <0.18, 0.10, 0.05, 0.3>]
               }
      scale <10., 10., 10.> 

       turbulence 1.00  
       lambda 2.8
       omega 0.6
       octaves 8
           }  

#declare Streaky_clear =

  pigment {

      bozo
    color_map {
      [0.00 color rgbt <0.15, 0.15, 0.15, 1.0>] 
      [1.00 color rgbt <0.15, 0.15, 0.15, 1.0>]
               }

      scale <10., 10., 10.> 

       turbulence 1.00  
       lambda 2.8
       omega 0.6
       octaves 8
           }  

//	Fade toward the middle

#declare Vertical_streaks =

pigment {
gradient x
pigment_map {
       [0.00 Streaky_clear ]
       [0.10 Streaky ]
       [0.50 Streaky_clear ]
       [0.90 Streaky ]
       [1.00 Streaky_clear ]
             }
	turbulence 0.15  // not totally vertical
        }

//	Fade as streaks near the bottom

#declare Streaks_pigment =

pigment {
gradient y
pigment_map {
       [0.00 Streaky_clear ]
       [0.80 Vertical_streaks ]
       [1.00 Vertical_streaks ]
             }
        }

//	Color the background

background { color rgb <.25, .35, .40>*.5 }

//	Display the scene

camera {
  location < 2.0, 5.5, -30.0>
  look_at  < 2.0, 5.5,   0.0>
  angle 30 
	    }

//	The sun
//	The brick wall was not designed for bright sunlight, so mortar
//	and brick colors should be adjusted for good results in sunlight

//light_source {<1000, 500, -500> color rgb < 1., 1., 1.>*3 }

//	Fill light

light_source {<-500, 500, -500> color rgb < 0.4, 0.4, 0.4> }

//	Horizon Clouds

#declare Horizon_clouds =

pigment {

  granite

  color_map {
    [0.00 color rgbt <1.0, 1.0, 0.9, 0.0>*0.5]  //  White
    [0.15 color rgbt <1.0, 1.0, 0.9, 0.0>*0.5]  //  White

    [0.25 color rgbt <1.0, 0.9, 0.7, 0.2>*0.5]  //  White-Yellow 
    [0.30 color rgbt <1.0, 0.9, 0.9, 0.4>*0.5]  //  White-Yellow  
    [0.35 color rgbt <1.0, 0.9, 0.7, 0.5>*0.5]  //  White-Yellow 

    [0.45 color rgbt <1.0, 1.0, 0.9, 1.0>*0.5]
    [1.00 color rgbt <1.0, 1.0, 0.9, 1.0>*0.5]
  	         }

turbulence 0.1  
scale <2.0, 0.2, 2.0>
	     }

//	Sky

sky_sphere {
    pigment {
        gradient y
        pigment_map {

    [0.00 Horizon_clouds ]
    [0.01 Horizon_clouds ]
    [0.05 color rgb < .25, .35, .40 >*0.9]  // Gray blue sky Light horizon
    [0.19 color rgb < .25, .35, .40 >*0.2]  // Gray blue sky Dark 
        			 }
    		}
		   }

//	Fog

fog{
    color rgb <0.6, 0.55, 0.57> 
    fog_type 2
    fog_alt 18
    fog_offset 0
    distance 5000
	turbulence < 1., 1., 1.>
    }

//	Lamp (includes a light source)

object { VeniceLamp 
		 rotate (105.0 + WallRot)*y
		 translate <0.0, 9.5, 0.0> }

//	The brick walls (draws two walls with a corner)

object { BrickWall(12.0, 9.9, 4.8) 
	 rotate WallRot*y 
	    }

//	The window frame (the window's hole is created in BrickWall)

object {
	difference {
		union {
  			box { <3.75, 2.75, -0.15>, <7.25, 6.5, 0.5> }
  			cylinder { <5.5, 6.5, -0.15>, <5.5, 6.5, 0.5>, 1.75 }
       		   }
         box { < 4.1, 3.1, -1.0>, < 6.9, 6.5, 11.0> }
         cylinder { < 5.5, 6.5, -1.0>, < 5.5, 6.5, 11.0>, 1.4 }
	     		}  //  end of difference

	texture { MottledMarble_texture }
	rotate WallRot*y
	   }

//	The water streaks under the window

object {
        box { <0.0, 0.0, 0.0>, <3.8, -2.75, 0.001> }
        pigment { Streaks_pigment
			translate <10.0, 0.0, 0.0>
        	scale <3.8, 4.0, 1.0>
                 }
        translate <3.7, 2.75, -0.04>
		rotate WallRot*y
        no_shadow
        }

//	The quions (comment out to see brick corner normal problem)

#local QuionHeight = 0.25;
#while ( QuionHeight < 9.0 ) 

object {

    superellipsoid { <.08, .08>
					  scale 0.5
					  translate <0.35, 0.45, 0.35>
					}
	rotate WallRot*y
	translate <0., QuionHeight, 0.>
	texture { MottledMarble_texture }
		}

#local QuionHeight = QuionHeight + 1.4;
#end

//      Dark Water (ripple reflection)

plane { y, 0.0

  finish { ambient 0.00
           diffuse 0.00 
           reflection 0.08
          }

  pigment { color rgb < 0.0, 0.08, 0.0> }

normal { ripples 0.3 frequency 1 scale < 5., 1., 5. > }

      }