// Persistence of Vision Ray Tracer Scene Description File
// File: wpool.pov
// Vers: 3.5
// Desc: Photons and water test
// Date: Sept. 2001
// Auth: Jaime Vives Piqueres
//

#version 3.5;

// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions

// ==== Additional Includes ====
#include "FINISH.INC"   // Some basic finishes
#include "SKIES.INC"    // Ready defined sky spheres


// ==== Global settings ====
#declare Photons=on;
global_settings {
  max_trace_level 15
  ambient_light 0.0 
  radiosity{} // no +qr! Nice... :)
  #if (Photons)          // global photon block
    photons {
      spacing 0.0125                 // increase to .00125 for a good effect
    }
  #end
}


// ==== sky to reflect ====
sky_sphere {S_Cloud2}


// ==== terrain ====
plane {
  y, 0 
  hollow
  texture{pigment {Tan}}
}


// ==== pool ===
union{     
 // pool
 difference{
  box{-.5,.5}
  box{-.5,.5 scale .9 translate .11*y}
  hollow
  scale <2,.5,2>
  texture{
   pigment{
    brick color SkyBlue color Turquoise
   }
   scale <.01,.02,.01>
   scale .5
  }
  translate .25*y
 }
 // exterior construction
 difference{
  box{-.5,.5}
  box{-.5,.5 scale <.9,1.1,.9>}
  box{-.5,.5 scale <1.1,.9,.9>}
  box{-.5,.5 scale <.9,.9,1.1>}
  hollow
  scale <4,2,4>
  pigment{
   brick color Wheat color Firebrick
   scale .02
  }
  translate 1*y
 }
 // water solid  
 height_field {
  function 400,400 {
   pigment {
    bumps turbulence .1
    color_map {
     [0 rgb .98]
     [1 rgb 1]
    }
    scale .05
   }
  }
  translate -0.5
  scale .89 
  hollow
  photons {  
    target 1.0
    refraction on
    reflection on
  }
  scale <2,.5,2>
  material { // water material
   texture {
     pigment {rgbt .95}
     finish {
       specular 1
       roughness 0.001
       ambient 0
       diffuse 0
       reflection {
         0.1, 1.0
         fresnel on
       }
       conserve_energy
     }
   }
   interior {
     ior 1.33
     fade_power 4
     fade_distance 1
     fade_color SummerSky    
   }
  }
  translate .25*y
 }
 rotate 30*y
}


// ==== typical ball ====
union{
 #declare n=0;
 #while (n<6)
  sphere{0,.1 scale <.9,1,1> rotate n*(360/6)*y}
  #declare n=n+1;
 #end
 texture{
  pigment{
   radial
   color_map{
    [0.0 White]
    [0.5 White]
    [0.5 Red]
    [1.0 Red] 
   }
   frequency 6
  }
  finish{Shiny reflection{.05,.2}}
 }
 rotate <30,24,147>
 translate .55*y
}


camera {
  location  <0,1,-2>
  direction 1.7*z
  look_at   <-.01,0.25,0>
}

light_source {
  <-500,1500,-1500>       
  White*.8+Gold*.1
  fade_distance 10000
  fade_power 2       
  photons {          
    refraction on
    reflection on
  }
}