global_settings{
  assumed_gamma 1
  max_trace_level 15
}

camera {
  location <0, 2, -5>*2
  right x
  direction 3*z
  look_at <0, 0.3, 0>
}

merge{
  merge{
    torus{0.625,0.025 translate 1.5*y}
    difference{
      cylinder{-y*0.99,y*1.5,0.65}
      cylinder{-y*0.7,y*1.51,0.6001}
    }
    pigment {color rgbt<1,1,1,1>}
    finish{diffuse 0 ambient 0 specular 2 roughness 0.005 reflection{0.5 fresnel on}}
    interior{ior 1.5  fade_distance 1.5 fade_power 1000 fade_color rgb<0,0.1,0.05>}
  }

  difference{
    cylinder{-y*0.699,y*0.8,0.6}
    #declare R=0.03;
    union{
      torus{0.6-R,R}
      cylinder{-R*y,R*y,0.6-R}
      translate y*0.8
    }
    hollow
	  texture{
	    pigment{color rgbt<1,1,1,0.85>} finish{diffuse 0 ambient 0}
	  }
	  interior{
		  media{  
		    #declare Diffuse=1.7;      
			  scattering {1, rgb <0.55,0.6,1>*10*Diffuse extinction 1/Diffuse}
			  intervals 1
			  samples 50
			  method 3
	    }
	  }
  }
}


light_source {
  <-10, 12,-13> 
  rgb 1
  media_interaction on
}

plane { y, -1 pigment {rgb<0.6,0.3,0.3> } finish{ambient 0 diffuse 0.26}}