// incoming.pov  
//
// A shaders test file by Mike Andrews (m.c.andrews@reading.ac.uk)
// 17th July 2001
  
// CAN ONLY BE USED WITH THE POVMan VARIANT OF POVRAY

#version unofficial MegaPov 0.7;

global_settings { 
  max_trace_level 10
  assumed_gamma 1
  ambient_light 1
#if(0)
  ini_option "+QR"
  radiosity { 
    pretrace_start 0.08
    pretrace_end   0.01
    count 50            
    nearest_count 5     
    error_bound 0.25    
    recursion_limit 2   
    low_error_factor .02
    gray_threshold 0.0  
    minimum_reuse 0.002 
    brightness 1        
    adc_bailout 0.01/2  
    normal on
  }
#end
#if(0)
  photons {
    count 1000000
    jitter 0.5
  }
#end
}

#declare BC = <pow(7/4,-4),pow(7/5.5,-4),1>;

background { color rgb BC*0.4 }
 
fog {
	fog_type 2
	colour rgb BC*0.3
	distance 100
	fog_alt 6
	fog_offset -7
}

fog {
	fog_type 2
	colour rgb (1-BC)*0.5
	distance 500
	fog_alt 15
	fog_offset -7
}

camera {
  up y
  right x*image_width/image_height
  direction 1.4*z
  location <-1,1,-10>*3
  look_at 0
}

light_source {  
  0*x   
  color rgb 1-0.1*BC
  area_light x, z, 5, 5
  circular
  orient
  jitter
  translate 50*vnormalize(<1,2,-2>)
  scale 400
	photons { reflection on refraction on }
}
  
#declare swirl = pigment {
  shader{
    shader_file "swirl2.slp"
    "Rot" 2
    "Power" 3
    "Dir" y
    "Steps" 9
    "Type" 0
    shadow_type shader_shadow
  }
}

#declare twirl = pigment {
  shader{
    shader_file "twirl.slp"
    "Rot" -2
    "Power" 3
    "Origin" <0,0,0>
    "Radius" 4
    "Dir" y
    shadow_type shader_shadow
  }
}

#declare incoming = pigment {
  shader{
    shader_file "incoming.slp"
    "falloff" 3
    "col1" <1,0.5,0>
    "col2" <1,0,0.2>
    shadow_type shader_shadow
  }
}

blob {
  threshold 0.4
  sphere {x,1.2,1 rotate 0*z}
  sphere {x,1.2,1 rotate 120*z}
  sphere {x,1.2,1 rotate 240*z}
  pigment { incoming }
  finish { ambient 0 diffuse 0.3 specular 0.5 metallic }
  normal { granite -1 scale 0.1 }
  scale 4
}

difference {
  box { -<8.1,10,8.1>,<8.1,10,8.1> } 
  box { -<8.1,10.1,8.1>,<8.1,10.1,8.1> translate <0.1,0,-0.1> }
  rotate  50*y 
  texture { 
    pigment { rgb 0.7*<.95,.97,.98> } 
    finish { ambient 0 diffuse 0.1 brilliance 10 specular 0.2 roughness 0.001 reflection 0.7*<.95,.97,.98> } 
    normal { bumps 0.002 }
  }
  photons { target refraction off reflection on ignore_photons }
}

#declare S = seed(1);

plane {
  y, -7
  texture{
    pigment{
      pigment_pattern {
        spherical
        pigment_map {
          [0 rgb 0]
          [0.5 radial rotate x*90 cubic_wave frequency 5 colour_map {[0 rgb 0][0.5 rgb 1][1 rgb 0]} ]
          [0.9 rgb 1]
        }
        scale 3/2
      }
      pigment_map {
        [0 rgb 1]
        [0.7 
          average
          pigment_map {
            [1 bozo colour_map {[0 rgb x][1/3 rgb y][2/3 rgb z][1 rgb x]} rotate <rand(S),rand(S),rand(S)>*360 translate (<rand(S),rand(S),rand(S)>-0.5)*200]
            [1 bozo colour_map {[0 rgb y][1/3 rgb z][2/3 rgb x][1 rgb y]} rotate <rand(S),rand(S),rand(S)>*360 translate (<rand(S),rand(S),rand(S)>-0.5)*200]
            [1 bozo colour_map {[0 rgb z][1/3 rgb x][2/3 rgb y][1 rgb z]} rotate <rand(S),rand(S),rand(S)>*360 translate (<rand(S),rand(S),rand(S)>-0.5)*200]
          }
        ]
      }
      scale 3
      scale 1/2
      warp { displace { swirl type 0 } }
      scale 2
      warp { displace { twirl type 0 } }
      scale 1/2
      scale 5
      warp { displace { swirl type 0 } }
      scale 2
      
    }
    finish { diffuse 0.4 ambient 0 }
  }
}