// ************************************************************************
//   BLob_SHIP 3.POV                                       
//   Michael Brendan Hurley for ShadowDancer Enterprizes, LTD.          
//   Odds and Ends Tester ... b-series                                  
//   Blobby Space Ship ver. A, beauty shot                    6 Oct 97  
//
//   REVISED FOR ver 3.1g...                                 July 2001
//   Galaxy effects from C. Colfax as seen in Gini_07.pov
//
// ************************************************************************

// ************************************************************************
//                           Global Definitions                         
// ************************************************************************

#include "brendan.inc"                 // Lights Cameras Simple objects

#declare ShowDetails = true;
#declare FullTexture = true;
#declare ShowGalaxy  = true;
#declare ShowPlanet  = true;

// ************************************************************************
//                           Scene Definitions
// ************************************************************************

// ************************************************************************
// Define Sky                                                        
// ************************************************************************

//background { color LightBlue }
//sky_sphere { pigment  { LightBlue } }            // day

//background { color Black }
//sky_sphere { pigment { Black } }            // day

// ************************************************************************
// LIGHTS!
// ************************************************************************

/*
#declare FloodSE1 =
light_source { < 1000 500 -1000 >
               color White
             }  //end light Flood SE 1

#declare FloodSE2 =
light_source { < 500  700 -500 >
               color White
             }  //end of SE 2

#declare FloodSW1 =
light_source { < -1000 500 -1000 >
               color White
             }  //end light Flood SW 1

#declare FloodSW2 =
light_source { < -500 700 -500 >
               color White
             }  //end light Flood SW 2

#declare FloodNE1 =
light_source { < 1000 500 1000 >
               color White
             }  //end of NE 1

#declare FloodNE2 =
light_source { < 500 700 500 >
               color White
             }  //end of NE 2

#declare FloodNW1 =
light_source { < -1000 500 1000 >
               color White
             }  //end of NW 1

#declare FloodNW2 =
light_source { < -500 700 500 >
               color White
             }  //end of NW 2

#declare FloodRear =
light_source
    { < -100 1000 1000 >
      color White
     }  //end light FloodRear

#declare FloodSouth =
light_source {
   < 0 100 -1000 >
   color White
             }  //end light SouthFlood
*/
//object { FloodRear }  
//object { FloodSouth }
//object { FloodSE1 }
//object { FloodSW2 }

// *******************************************************************
// *******************************************************************
// Define Ambient Lights

light_source { <   0,   0, 1100 > color LightBlue }    // galaxy glow
light_source { < 180, -30,  450 > color White }        // planet's sun


// ************************************************************************
// CAMERA!
// ************************************************************************

#declare TestView =
camera {
  direction < 0, 0, 8 >
  location < 7, 0, -65 >            // due south
//  location < 25, 5, -35 >            // near SE
  look_at < 7, 0, 0 >                  // scene center
       }  //end of camera Test View

#declare Narrow =
camera {
   location < 0, 0, -400 >
   look_at  < 0, 0, 1 >
   angle 30               // NARROW TO PREVENT DISTORTION
       } // end camera

//camera { TestView }
camera { Narrow }

// ************************************************************************
//  DEFINE OBJECTS!
// ************************************************************************

#declare mbh_Metal =
finish {
    metallic
    ambient 0.7
    diffuse 0.7
    brilliance 3
    reflection 0.85
    phong 0.2
    phong_size 4
       }//end finish

#declare Silver_Texture = 
texture { pigment { rgb < 0.90, 0.91, 0.98 > }
          finish { mbh_Metal } }

#declare Silver_Metal = texture { Silver_Texture }

// *******************************************************************

// DECLARE TEXTURE ***** Green surface
#declare Green_World =
texture {
   pigment {
      wood
         turbulence 1.25
         color_map {
            [ 0.0  0.6  color LimeGreen  color ForestGreen ]
            [ 0.1  0.6  color Yellow     color LimeGreen ]
            [ 0.6  1.0  color LimeGreen  color Clear ]
                   }  //end color map
         scale < 3.5, 1.0, 1.0 >
         quick_color Green
           }// end pigment
   finish {
      diffuse 0.55
      brilliance 0.2
      reflection 0.1
          }// end finish
        }  //end texture  Green World

// *******************************************************************
// *******************************************************************

//   DEFINE a pod-shape: symetrical lumpy masses
#declare BigBlob_2 =
blob {
   threshold .08
   sphere { < 0,  4.80, 0 >, 2.2, 0.9 }
   sphere { < 0,  1.55, 0 >, 3.9, 1.0 }
   sphere { < 0, -1.55, 0 >, 3.9, 1.0 }
   sphere { < 0, -4.80, 0 >, 2.2, 0.9 }
   hollow
   #if ( FullTexture = true )
      texture { Silver_Metal }
   #else   
      texture { Blue_Tex }
   #end
     } //end big blob 2

// *******************************************************************

//   DEFINE  Elliptical tube   *****
#declare Fin_A =
object {                                 
   superellipsoid { < 1, 0.2 >
      scale < 0.7, 7.5, 0.7 >
      hollow
      #if ( FullTexture = true )
         texture { Silver_Metal }
      #else   
         texture { Green_Tex }
      #end
                  }//end ellip.
       } // end obj Fin

// *******************************************************************

//   DEFINE  Elliptical sauser   *****
#declare Disk_A =
object {
   difference {
      object { Ellipsoid  scale < 1.0, 3.5, 3.5 > }
      object { Ellipsoid  scale < 0.5, 4.0, 4.0 > }
              }// end difference disk A
      hollow
      #if ( FullTexture = true )
         texture { Silver_Metal }
      #else   
         texture { Red_Tex }
      #end
       } // end obj Disk A

// *******************************************************************

//   DEFINE  Elliptical glass pod
#declare Disk_B =
object {
   Ellipsoid
      hollow  
      scale < 0.5, 4, 4 >
      #if ( FullTexture = true )
         texture { T_Glass1 }
      #else   
         texture { Yellow_Tex }
      #end  
       } // end obj Window Section

// *******************************************************************

//    DEFINE  elliptical light source
#declare Disk_C =
light_source {
   < 0, 0, 0 >
   color Yellow
   looks_like { Disk_B }
   fade_distance 40
   fade_power 2
                } // end light source  

// *******************************************************************
// *******************************************************************

//   DEFINE  Chubby space ship  standing on tail
#declare BlobShip_A =
union{
   object { BigBlob_2 }
   object { Disk_A translate <  0.0, 4.8,  0.0 > }
//   object { Disk_B translate <  0.0, 5.0,  0.0 > }
   object { Disk_C translate <  0.0, 5.0,  0.0 > }
   object { Fin_A  translate < -2.5, 0.0,  2.5 > }
   object { Fin_A  translate <  2.5, 0.0,  2.5 > }
   object { Fin_A  translate <  2.5, 0.0, -2.5 > }
   object { Fin_A  translate < -2.5, 0.0, -2.5 > }
          } // end Blobby Ship A


// ************************************************************************
// ACTION!
// ************************************************************************

//object { Check_Floor  translate < 0, -200, 0 > }

// *******************************************************************

#if ( ShowPlanet = true )
object { Sphere                        //planet
         texture { Green_World }
         scale 30
         translate < 90, 55, 440 >
       }  // end sphere

object { Sphere                        //moon
         texture { Gray25_Tex }
         scale 7
         translate < 35, 60, 400 >
       }  // end sphere
#end  // of Show Planet

// ***********************************************************************

#if ( ShowGalaxy = true )
   // COMMON GALAXY OPTIONS
//   #declare debug_options = true;
   #declare options_only = true;
   #declare galaxy_seed = 9696;
   #declare galaxy_colour1 = < 1.1, 1.0, 1.7 >;
   #declare galaxy_colour2 = < 0.5, 0.4, 0.8 >;
   #declare galaxy_colour2 = < 0.4, 0.4, 0.7 >;

   // GALAXY OBJECTS
   #declare galaxy_object_scale = 2.5;
   #declare galaxy_object_position = < 0, 0, -200 >;
   #declare galaxy_object_rotate = 33;
   #declare galaxy_object_flatten = 0.6;
   #declare galaxy_pattern_origin = x * 1;
   #declare galaxy_turb_origin = x * 1;
   #declare galaxy_pattern_scale = 1.330;
   #declare galaxy_star_colouration = 0.450;
   #declare galaxy_cluster_objects = 4;
   #declare galaxy_object_name = "Galaxy5"
   #include "GALAXY.OBJ";

   // GALAXY STAR FIELD
   #declare star_count = 6000;
   #declare star_colour =  < 0.75, 0.75, 0.90 >;
   #declare star_distribution = 0.3;
   #declare star_brightness_turb = 0.6;
   #declare star_colour_turb = 0.8;
   #include "GALAXY.SF";

   // GALAXY BACKGROUND
   #declare galaxy_bgstars = 2;
   #declare galaxy_bgnebula = 1;        //default
   #declare galaxy_nebula_ambient = < 0.29, 0.25, 0.34 >;
   #include "GALAXY.BG";
#end  //of Show Galaxy

// *******************************************************************
// *******************************************************************

object { BlobShip_A
//            rotate <   0,   0,   0 >   // stands on its tail
            rotate < -30, 20, 270 >   // faces S beauty shot
//            rotate <   0,   0, -90 >   // faces E
//            rotate <   0,   0,  90 >   // faces W
//            rotate <   0,  40,   0 >   // rotates on its tail
//            rotate <  90,   0,  90 >   // faces N on its side
//            rotate < -90,   0,  90 >   // faces S on its side
            translate < -10, 0, -320 >        // relocate ship
       } // end Blob Ship A

// ************************************************************************
// END  BL_SHIP2   FILE
// ************************************************************************