// Persistence of Vision Ray Tracer Scene Description File
// File: elf.pov
// Vers: 3.1
// Desc: my elf logo
// Date: 09/20/99
// Auth: Eric L. Freeman
#version unofficial MegaPov 0.5;

// ==== Standard POV-Ray Includes ====
#include "kolors.inc"
#include "mega_metals.inc"

// Lights
$LiteDist = 300000;
$LiteRad = 0.003;
$LiteFall = 0.008;
$LiteTite = 5;
// E
light_source {
  <LiteDist,0,0>
  color rgb <0,0,1>
  spotlight
  point_at <0, 0, 0>
  radius LiteRad
  tightness LiteTite // lower is softer, higher is tighter
  falloff LiteFall   // intensity falloff radius (outer, in degrees)
}
// L
light_source {
  <0,0,-LiteDist>
  color rgb <1,0,0>
  spotlight
  point_at <0, 0, 0>
  radius LiteRad
  tightness LiteTite // lower is softer, higher is tighter
  falloff LiteFall   // intensity falloff radius (outer, in degrees)
}

// F
light_source {
  <0,LiteDist,0>
  color rgb <0,1,0>
  spotlight
  point_at <0, 0, 0>
  radius LiteRad
  tightness LiteTite // lower is softer, higher is tighter
  falloff LiteFall   // intensity falloff radius (outer, in degrees)
}

// Walls
$WallOffset = -44;
/*
$WallFin = finish {
  reflection <0.3,0.17,0.5>
  ambient 0.08
  diffuse 0.92
}
$WallTex = texture {
  pigment {color Gray40}
  finish {WallFin}
}
*/
$WallMat = material {
  texture {
    pigment {color Gray40}     // use any pigment you like.
    finish {
      ambient 0.08
      brilliance 2
      diffuse 0.92
      metallic
      reflect_metallic
      blinn 2.0 facets 0.28
      reflection <0.3,0.24,0.44>*2.3
    }
  }
  interior {MegaMetalInt}
}

plane {
  <0,1,0>,
  WallOffset
//  texture {WallTex}
  material {WallMat}
}

plane {
  <0,0,-1>,
  WallOffset
//  texture {WallTex}
  material {WallMat}
}

plane {
  <1,0,0>,
  WallOffset
//  texture {WallTex}
  material {WallMat}
}

// WALL CORNERS
$CorTex = texture {
  pigment {color Gray70}
  finish {
    reflection 0.0
    ambient 0.13
    diffuse 0.87
  }
}
$CorRad = 1;
cylinder {
  <WallOffset,WallOffset,-WallOffset>,
  <WallOffset,1000,-WallOffset>
  CorRad
  texture {CorTex}
}
cylinder {
  <WallOffset,WallOffset,-WallOffset>,
  <1000,WallOffset,-WallOffset>
  CorRad
  texture {CorTex}
}
cylinder {
  <WallOffset,WallOffset,-WallOffset>,
  <WallOffset,WallOffset,-1000>
  CorRad
  texture {CorTex}
}

// THE BLOCK
$CutOut = 4.0;
$Solid = CutOut*1.9;
$BlockX = (CutOut*2)+(Solid*3);
$BlockSp = BlockX/2;
$BoxFin = finish {
  reflection 0.0
  ambient 0.2
  diffuse 0.8
}
$BoxTex = texture {
  pigment {color Gray50}
  finish {BoxFin}
}

$BoxMat = material {
  texture {
    pigment {color Gray50}
    finish {
      ambient 0.2
      brilliance 2
      diffuse 0.8
      metallic
      reflect_metallic
      blinn 2.0 facets 0.28
      reflection 0.05
    }
  }
  interior {MegaMetalInt}
}

$Block = difference {
  box {
    <-BlockSp,-BlockSp,-BlockSp>,
    <BlockSp,BlockSp,BlockSp>
  }
  // E
  box {// top cutout
    <-BlockSp-1,-BlockSp+CutOut+(Solid*2),-BlockSp+Solid>,
    <BlockSp+1,-BlockSp+(CutOut*2)+(Solid*2),BlockSp+1>
  }
  box {// bottom cutout
    <-BlockSp-1,-BlockSp+Solid,-BlockSp+Solid>,
    <BlockSp+1,-BlockSp+CutOut+Solid,BlockSp+1>
  }
  box {// rite cutout
    <-BlockSp-1,-BlockSp+CutOut+Solid-0.1,-BlockSp+(Solid*2)+(CutOut*2)-0.0001>,
    <BlockSp+1,-BlockSp+CutOut+(Solid*2)+0.1,BlockSp+1>
  }
  // L
  box {
    <-BlockSp+Solid+0.0001,-BlockSp+Solid+0.0001,-BlockSp-1>,
    <BlockSp+1,BlockSp+1,BlockSp+1>
  }
  // F
  box {// top cutout
    <-BlockSp+Solid,-BlockSp-1,-BlockSp+(Solid*2)+CutOut>,
    <BlockSp+1,BlockSp+1,-BlockSp+(Solid*2)+(CutOut*2)>
  }
  box {// bottom cutout
    <-BlockSp+Solid,-BlockSp-1,-BlockSp-1>,
    <BlockSp+1,BlockSp+1,-BlockSp+Solid+CutOut>
  }
  box {// rite cutout
    <-BlockSp+(Solid*2)+CutOut,-BlockSp-1,-BlockSp+Solid+CutOut-0.0001>,
    <BlockSp+1,BlockSp+1,-BlockSp+(Solid*2)+CutOut+0.0001>
  }
//  texture {BoxTex}
  material {BoxMat}
}
object {Block}

// set viewer's position in the scene
$CamX = 100000;
$CamAng = 0.1; //0.06;

$CamPos = <CamX,CamX,-CamX>;
$CamLook = <0,-CamX*0.00005,0>;
camera {
  location CamPos
  look_at CamLook
  angle CamAng
}