//----------------------------------------------------
//       wobbling logo
//            with
//      bubbling bubbles
//
//   09.2000 by Karl Pelzer
//
// requirements: Megapov
//               spray.inc, AutoClck.mcr by Chris Colefax
//
// ~100 frames cyclic
//----------------------------------------------------

#version unofficial MegaPov 0.5;

#include "colors.inc"              
#include "AutoClck.mcr"

#macro wobbletext(testtext,ypos)
        #local textforlen = text{ttf font, testtext 0.5, 0}   // declare to get the half 
        #local centre = max_extent(textforlen).x/2;           // extent in x direction -> center around the origin
                                                              // (not absolutely true beacuse of the different char
                                                              // spacing used in pov-ray's text-object)   
        #local len = strlen(testtext);                        // how many chars in the string ?
        #local charspacing = 1.1;                             // spacing of 1 means no spacing
        #local counter = 0;
        #while (counter<len)
                #local versatz = counter/50;
                #local character = text{
                                            ttf font, substr(testtext,len-counter,1) 0.5, 0
                                            scale From(0+versatz,1) To_Using(0.3+versatz,0.8, "J") To_Using(0.6+versatz,0.7, "J") To_Using(0.88+versatz,0.8, "J")
                                         }              
                #local xwidth = max_extent(character).x;      // extent of the character in x direction 
                #local centre = centre-(xwidth*charspacing);  // next char position
                object { 
                        character
                        translate <centre,ypos,1.5> 
                        pigment {color rgb <0.7,0.9,0>}
                        finish {ambient .9 diffuse .4 reflection 0.0 specular 0 roughness 1}  
                        }
                #local counter = counter +1;                  // next character
        #end
#end

//----------------------------------------------------

global_settings
{
  post_process {overwrite_file find_edges{10, 1, .01, 1, 1.0, rgb 0}}  
  assumed_gamma 1.0
  max_trace_level 15
}

camera
{
  location  <0.0, 0.5, -4.0>
  direction 1.5*z
  right     4/3*x
  look_at   <0.0, 0.0,  0.0>
}

background {<1,1,1>}

light_source {-30*z color rgb 1 shadowless}                   // orthogonal related to the text

#declare font = "actionis.ttf"                                // select a groovy font
wobbletext ("Austin",0.1)                            
wobbletext ("Powers",-1.0)

// FIRST SPRAY
   #declare spray_loop = true;
   #declare spray_location = <-4, 0, 4>;
   #declare spray_direction = <1, 0, 0>;
   #declare spray_strength = 4;
   #declare spray_gravity = 0;

   #declare particle_count = 30;
   #declare particle_life = 3;
   #declare particle_stretch = 1;
   #declare particle_dist = .6;
   #declare particle_size = 0.4;
   #declare particle_sep = 0.5;
   
   #declare nozzle_angle = 30;
   #declare nozzle_spin = 3;

   #declare spray_texture = texture {
                                     pigment {color rgbft<0.6,0.2,0.7,1,0.5>}
                                     finish {ambient 1 diffuse 0 brilliance 1 specular 0}
                                    }
   #declare spray_turb = .1;
   #declare angle_turb = 3;
   #declare spin_turb = 3;
   #declare vel_turb = 0.7;
// CREATE SPRAY OBJECT
   #include "Spray.inc"

// SECOND SPRAY
   #declare spray_loop = true;
   #declare spray_location = <2, 0.5, -1>;
   #declare spray_direction = <-1, 0, 0>;
   #declare spray_strength = 3;
   #declare spray_gravity = 0;

   #declare particle_count = 80;
   #declare particle_life = 3;
   #declare particle_stretch = 1;
   #declare particle_dist = .6;
   #declare particle_size = 0.2;
   #declare particle_sep = 0.5;
   
   #declare nozzle_angle = 30;
   #declare nozzle_spin = 3;

   #declare spray_texture = texture {
                                     pigment {color rgbft<0.2, 0.2, 1, 1, 0.5>}
                                     finish {ambient 1 diffuse 0 brilliance 1 specular 0}
                                    }
   #declare spray_turb = .1;
   #declare angle_turb = 2;
   #declare spin_turb = 2;
   #declare vel_turb = 0.7;

// CREATE SPRAY OBJECT
   #include "Spray.inc"