#include "colors.inc"
#version unofficial Megapov 0.5;
global_settings{
        ini_option "+QR"
        radiosity{
        pretrace_start 0.16
        pretrace_end   0.01
        count 300             
//        count 30          //plus rapide, moins joli    
        nearest_count 4      
        error_bound 0.1      
        recursion_limit 1    
        low_error_factor 1  
        gray_threshold 0.5  
        minimum_reuse 0.015 
        brightness 1.2      
        adc_bailout 0.01/2  
        }
}        
camera{location  <0, 6, -10>  direction 2*z  right     4/3*x  look_at   <0, 1.5,  0>}
//light_source{<-1000,1000,-1000> color White*0.4     area_light 1000*x,1000*y 8,8 orient jitter}
sky_sphere{pigment{gradient z poly_wave 2 color_map{[0 White][1 White*0.5]} translate -z*0.5 scale 2}}
#declare rP=5;
#declare rd=seed(0);
union{
    #declare i=0;
    #declare em=0.5;
    #while (i<40)      
        union{
            difference{
                #declare xbg=5*(1+rand(rd));
                #declare xbd=5*(1+rand(rd));
                #declare yb=7+8*rand(rd);
                #declare zb=1+rand(rd)*10;
                box{<-xbg,0,-3>,<xbd,yb,zb>}
                box{<-xbg+em,em,zb-em>,<xbd-em,yb-em,zb+em>}
                #declare rb=min(yb,xbg+xbd)*0.45*(1-rand(rd)*0.5);
                sphere{0,1 scale <rb,rb,3> translate <(xbg+xbd)*0.5-xbg,yb*0.5,zb>}
            }
            sphere{0,1 scale <rb*0.5,rb*0.5,3> translate <(xbg+xbd)*0.5-xbg,yb*0.5,zb-3>}
            torus{rb,rb*0.1 rotate x*90 translate <(xbg+xbd)*0.5-xbg,yb*0.5,zb>}
            translate <0,rand(rd)*30,rP>
            rotate y*rand(rd)*360
            texture{
                pigment{
                    bozo
                    color_map{
                        [0.5 rgb<rand(rd),rand(rd),rand(rd)>*1.2]
                        [0.5 rgb<rand(rd),rand(rd),rand(rd)>*1.2]
                    }
                }
                finish{ambient 0 diffuse 1}
                scale 5
                translate rand(rd)*100
            }
            
        }
        #declare i=i+1;
    #end
    texture{
        pigment{
            bozo
            color_map{
                [0.5 rgb<1,0.998,0.995>]
                [0.5 Red]
            }
        }
        finish{ambient 0 diffuse 1}
    }
    scale 0.1
}
plane{y,0 texture{pigment{White} finish{ambient 0 diffuse 1}}}