// Faking infinitely small rings on metal
// By Rune S. Johansen, August 2000

#version unofficial MegaPOV 0.5;

light_source {<0,1,1>*10, color 0.4 rotate 000*y}
light_source {<0,1,1>*10, color 0.8 rotate 240*y}
light_source {<0,1,1>*10, color 1.2 rotate 120*y}
light_source {<0,1,1>*10, color 0.5 shadowless}

camera {
   location <0,1,-2>*7
   angle 35
   look_at 0.5*y
}

plane {
   y, 0
   pigment {color rgb 0.7}
}

#declare A = 10; // Bump size

#declare Pigment = pigment {colour rgb <0.72,0.728,0.744>}
#declare Finish = finish {
   ambient 0.05
   diffuse 0.95
   specular 0.96
   roughness 0.0005
   phong 0.43
   phong_size 25
   brilliance 3.15
   reflection 0.33
   reflect_metallic
   metallic on
}

intersection {
   cylinder { // the faces of the cylinder
      0, y, 2.501
      texture {
         average
         texture_map {
            [
               pigment {Pigment}
               normal {wood +A ramp_wave rotate 90*x scale 3}
               finish {Finish}
            ]
            [
               pigment {Pigment}
               normal {wood -A ramp_wave rotate 90*x scale 3}
               finish {Finish}
            ]
         }
      }
   }
   cylinder { // the side of the cylinder
      -0.001*y, 1.001*y, 2.5
      texture {
         average
         texture_map {
            [
               pigment {Pigment}
               normal {gradient y, +A scale 2}
               finish {Finish}
            ]
            [
               pigment {Pigment}
               normal {gradient y, -A scale 2}
               finish {Finish}
            ]
         }
      }
   }
}