#version unofficial MegaPov 0.5;

global_settings {
 assumed_gamma 2.2     
 max_trace_level 100
 ambient_light 0.25
}

#include "colors.inc"

#declare cm1=
 camera{
  location <0,-5,-22>
  look_at <0,0,0>
 }

camera {cm1}

light_source{<20,600,-80> rgb 0.5 media_interaction on}

// GROUND
plane {y,-15 pigment {Wheat} normal {quilted 3 control0 0 control1 0 scale 10} finish {specular 0.5 roughness 0.1} hollow}

#declare Count1=0;
#declare Scaler=1;
#declare XTran=-3;
#declare YTran=-3;

// BUBBLES
union {
 blob {
  threshold 0.65
  sphere {0,15,1 scale <1,0.5,1>}
  sphere {0,9,-1 translate -6*y pigment {Scarlet}}
 }
 sphere {0,1 scale <2,1,2> rotate 13*z translate <-3,-1.5,0>}
 sphere {0,1 scale <2,1,2> rotate 13*z translate <-3,-1.5,0> rotate -90*y}
 sphere {0,1 scale <2,1,2> rotate 13*z translate <-3,-1.5,0> rotate 180*y}
 sphere {0,1 scale <2,1,2> rotate 13*z translate <-3,-1.5,0> rotate 90*y}
 sphere {0,1 scale <1,0.75,1> translate <-4,-2,0> rotate -45*y}
 sphere {0,1 scale <1,0.75,1> translate <-4,-2,0> rotate -135*y}
 sphere {0,1 scale <1,0.75,1> translate <-4,-2,0> rotate 45*y}
 sphere {0,1 scale <1,0.75,1> translate <-4,-2,0> rotate 135*y}
 #while (Count1 <= 10)
  sphere {0,0.5 scale Scaler translate <XTran,YTran,0> rotate (60*Count1)*y}
  #declare Count1=Count1+1;
  #declare Scaler=Scaler-0.08;
  #declare XTran=XTran+0.2;
  #declare YTran=YTran-0.4;
 #end
 pigment {rgbt 1}
}

// WALL
cylinder {<0,-100,0>,<0,100,0>,200
 open 
 scale <1,1,0.4>
 pigment {rgb<0.947,0.947,1>}
 normal {quilted 3 control0 0 control1 0 scale 10 rotate -45*z} 
 finish {specular 0.05 roughness 0.1} 
 hollow
}
 
// WATER/MEDIA
box {-100,100 
 pigment {rgbt 1}
 normal {ripples 1 scale 3 turbulence 0.4}
 interior {
  ior 1.5
  media {
   scattering {2, .1 extinction .25}
   method 3
   samples 1,1
   intervals 1
   ratio .99
   confidence .999
   variance 1/120
   density {
    marble
    turbulence 0.15
    density_map {
     [0 rgb<0.1,0.2,0.175>/5]
     [0.5 rgb <0.25,0.5,0.45>/5]
     [1 rgb<0.1,0.2,0.175>/5]
    }
    scale 10
    rotate 40*y
   }
  }
 }
 hollow
}