// Sigmund Kyrre Ås (c) 2000  sigmund@kyrre.net

#version unofficial MegaPov 0.5;
global_settings {
    #if(0)
    photons { 
        gather 20,100              
        spacing .001
        autostop 0
        max_trace_level 16
    }
    #end
    max_trace_level 140  
} 

camera {
   direction 1
   location <-2,2,-2>
   look_at <-.1,.35,0>
   angle 60
}

light_source {<5,4,-7>*2
    color rgb <.4,.4,.5>
    spotlight 
    point_at y*.1
    radius 7 falloff 15
    }
light_source {<-5,1.5,0>*2
    color rgb <.6,.5,.5>
    spotlight 
    point_at -x*.2
    radius 10 falloff 18
}
light_source {<3,20,3>
    color <.7,.8,.8>
    spotlight 
    point_at z*.3
    radius 6 falloff 10
}

$DiamondScale   = .8;
$TotalHeight    = 1.5;
$GirdleHeight   = .40;
$CrownShape     = .35;  // percent of GirdleHeight
$PavilionShape  = .60;  // percent of pavilion height
$Facets         = 8;
$Radius         = 1;
#include "brilliant2.inc"

#macro RenderVector(V,n)
#render concat( "<",str(V.x,n,n),", ",str(V.y,n,n),", ",str(V.z,n,n),">\n" )
#end

object {Diamond
    $A=atan2( R3,(Y5-Y3) ) ;
    rotate degrees(A)*z
    rotate 90*z
    rotate -y*20
    translate y*(sin(A)*TotalHeight)
    pigment {color rgb <.91,.94,1> filter .5 }
    interior {
         ior 2.417 
         fade_power 1000 fade_distance 25 
         dispersion 1.07 disp_nelems 40
    }
    finish {
     reflection .4 
     conserve_energy
    // reflection_min .03 reflection_max .5 reflection_falloff .5 
    }
    photons{        
        target
        refraction on
        reflection on
        ignore_photons
    }
} 

plane {y,-.001 pigment{ rgb .9 } finish{diffuse .7 brilliance 1.2} }

box{-20,20
    pigment {
        bozo
        color_map { 
            [0  rgb <232,239,249>/255]
            [.1 rgb <195,213,238>/255] 
            [.3 rgb <173,199,231>/255]
            [1  rgb <232,239,249>/255]
        }
        turbulence .1
        scale 6
   }
   finish {diffuse 1 ambient .1}
   no_shadow 
   hollow
}
#if(1)
global_settings {
    ini_option  "+QR"
    ini_option "Preview_Start_Size=16"
    ini_option "Preview_End_Size=8"
    radiosity{
        count 25
        nearest_count 4
        error_bound 2.5
        recursion_limit 2
        low_error_factor .5
        gray_threshold 0.0
        minimum_reuse 0.015
        brightness 1
        adc_bailout 0.01/(18*2)
    }
}
#end