#include "colors.inc"
#include "macros.inc"
#include "metals.inc"
#include "textures.inc"

// ---------------------------------------------- The basic scene junk ------------------------------------------

#version unofficial megapov 0.4;
camera { location <0,0,-8.5> look_at <0,0,0> /*angle 84*/ }
//light_source { <-400,200,-400> Gray80 }
//light_source { <400,400,-400> Gray80 }
light_source { <150,250,-500> White*1.4 }
background { color Gray70 }

// ------------------------------------------------------- Ring -------------------------------------------------

#declare ctr = 0;
#while (ctr<=1)
   sphere { <5.5,0,0>,(.3667+.7334*ctr)*.9 rotate -330*ctr*z scale <1,2/3,1>*.85
            pigment { color rgb<cos(ctr*pi/2*.8),sin(ctr*pi/2*.8),0>*.9 }
            finish { specular .9 roughness .003 } }
   #declare ctr=ctr+1/1000;
#end

// --------------------------------------------------- Iris colors ----------------------------------------------

#declare IrisB = array[09]{RichBlue
                          ,RichBlue
                          ,MediumBlue
                          ,DarkSlateBlue
                          ,MidnightBlue
                          ,MidnightBlue
                          ,SteelBlue
                          ,SteelBlue
                          ,SteelBlue
                          }

// -------------------------------------------------- Iris pigment ----------------------------------------------

#declare step=250;
#declare Rnd=seed(0);
#declare Iris_B = pigment {
   radial
   color_map {
      [0.0 IrisB[0]]
      #declare ctr=1;
      #while (ctr<step)
         #declare Pig=color rgb<0,0,0>;
         #declare tot=0;
         #declare ctr2=0;
         #while (ctr2<dimension_size(IrisB,1))
            #declare R=rand(Rnd);
            #declare Pig=Pig+IrisB[rand(Rnd)*dimension_size(IrisB,1)]*R;
            #declare tot=tot+R;
            #declare ctr2=ctr2+1;
         #end
         [ctr/step Pig/tot]
         #declare ctr=ctr+1;
      #end
      [1.0 IrisB[0]]
   }
}

// ------------------------------------------------------ Eyes --------------------------------------------------

union {
   difference {
      sphere { 0,2.2 }
      intersection {
         cylinder { <0,1.1,-3>,<0,1.1,0>,2.1 }
         cylinder { <0,-1.1,-3>,<0,-1.1,.1>,2.1 }
      }
      sphere { 0,2.01 }
      texture { T_Brass_2A } //finish { reflection .05 }
      normal { average normal_map {
         [1 crackle .9 scale .3 slope_map { [0.0,<-.5,1>][0.2,<.5,.4>][0.5 <.4,-.1>][1.0 <.4,0>] }]
         [0.5 bumps .4 scale .01]
         [0.5 bumps .4 scale .03]
      } }
   }
   sphere {
      0,2
      texture {
         gradient z
         texture_map {
            [0.000 pigment { crackle color_map { [0.0 Red][0.02 Red][0.04 rgb<.9,.82,.8>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.750 pigment { crackle color_map { [0.0 Red][0.02 Red][0.04 rgb<.95,.94,.93>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.840 pigment { crackle color_map { [0.0 Red][0.015 Red][0.035 rgb<.9,.82,.8>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.910 pigment { crackle color_map { [0.0 Red][0.00 Red][0.01 rgb<.94,.85,.85>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.930 pigment { crackle color_map { [0.0 rgb<.94,.85,.85>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.940 pigment { crackle color_map { [0.0 rgb<.94,.85,.85>][1.0 rgb<.95,.94,.93>] }
                   turbulence .9 scale .15 } finish { specular .9 roughness .004 reflection .1 } ]
                   
            [0.950 pigment { Iris_B } finish { specular .8 roughness .004 metallic reflection .05 }
                   normal { average normal_map { [1 radial .2 slope_map { [0.0 <-.5,0>][0.25 <0,1>][0.5 <.5,0>][0.75 <0,-1>]
                   [1.0 <-.5,0>] } frequency 100 sine_wave][1 bumps .4 scale .02] } } rotate 90*x ]
            
            [0.984 pigment { Iris_B } finish { specular .8 roughness .004 metallic reflection .05 }
                   normal { average normal_map { [1 radial .2 slope_map { [0.0 <-.5,0>][0.25 <0,1>][0.5 <.5,0>][0.75 <0,-1>]
                   [1.0 <-.5,0>] } frequency 100 sine_wave][1 bumps .4 scale .02] } } rotate 90*x ]
            
            [0.986 pigment { color Black } finish { reflection .8 } ]
            
            [1.000 pigment { color Black } finish { reflection .8 } ]
         }
         scale 4.02*<1,1,-1> translate 2.01*z
      }
   }
}

// -------------------------------------------------- Fire texture ----------------------------------------------

#declare Fire = texture {
   pigment {
      gradient y
      color_map {
         [0.00 rgb<1,.8,0>*.8]
         [0.40 rgb<1,.65,0>*.8]
         [0.46 rgb<1,.4,0>*.8]
         [0.51 rgb<1,0,0>*.8]
         [0.57 rgb<.4,.4,.4>*.8]
         [0.70 rgb<.7,.7,.7>*.8]
         [1.00 rgb<0,0,0>*.8]
      }
      turbulence <.2,.4,.2>
      octaves 7
      lambda 3.2
      omega .5
      //scale <150,200,150>
      //translate -80*y
   }
   finish {
      ambient 1
      diffuse 0
   }
}

// -------------------------------------------------- Fire cylinders --------------------------------------------

merge {
   cylinder { <0,-41,0>,<0,41,0>,30 }
   cylinder { <-7,-41,9>,<7,41,9>,30 }
   cylinder { <-7,-41,9>,<7,41,9>,30 }
   hollow no_shadow no_image
   texture { Fire scale <150,200,150> translate -85*y rotate 290*y }
   translate -30*z
}