//#version unofficial MegaPov 0.4;

#include "colors.inc"

global_settings {
 assumed_gamma 2.2     
 max_trace_level 70
 ambient_light 0.100
}

#declare Cm1=
 camera {
  location <0,90, -75>
  direction <0, 0, 1>
  up  <0, 1, 0>
  right <4/3, 0, 0>
  look_at <0,40,0>
 }

camera {Cm1}

light_source {<50, 150, -50> color rgb 0.6}// fade_distance 50 fade_power 1.5}
light_source {<-50, 150, -50> color rgb 0.6}// fade_distance 50 fade_power 1.5}
light_source {<0, 10, -150> color rgb 0.6}// fade_distance 50 fade_power 1.5}


plane {y,-1 
 pigment {White}
}

#declare Original=
 blob {
  threshold .3
  sphere {0,1,-2
   translate 3.2*y
   scale <1.5,1,1.5>
  }
  sphere {0,1,0.6
   translate 3*y
   scale <3,1,3>
  }
  sphere {0,1,0.6
   translate 3*y
   scale <1.5,1,1.5>
  }
  sphere {0,1,0.6
   translate 2.15*y
   scale <1.4,1,1.4>
  }
  sphere {0,1,0.6
   translate 1.2*y
  }
  sphere {0,1,0.6
   translate 0.2*y
   scale <0.90,1,0.90>
  }
  sphere {0,1,0.6
   translate -0.8*y
   scale <0.85,1,0.85>
  }
  sphere {0,1,0.6
   translate -1.8*y
   scale <0.8,1,0.8>
  }
  sphere {0,1,0.6
   translate -2.8*y
   scale <0.75,1,0.75>
  }
  sphere {0,1,0.6
   translate -3.8*y
   scale <0.7,1,0.7>
  }
  sphere {0,1,0.6
   translate -4.8*y
   scale <0.65,1,0.65>
  }
  sphere {0,1,0.6
   translate -5.8*y
   scale <0.6,1,0.6>
  }
  sphere {0,1,0.6
   translate -7*y
   scale <0.8,1,0.8>
  }
  texture {
   pigment {rgb <.60, .75, .60>}
   finish {
    phong .4
    phong_size .9
    ambient .15
    metallic .6
    diffuse .6
    brilliance .8
   }
  }
 }

// O.K., you have very specific placement and scaling of each component, 
// rather than having an incrimented scaling and translation. It's interesting 
// that you scale after translation. I try to avoid that whereever possible, 
// as objects not at the origin point will move as well as resize when you scale them.
//
// So, I'm going to try loops of ten components between each original component location.
// For the two major components at the top, I kept their original radius and strength.
// FOr all the rest, as I was going to use 10 components for each of the originals, 
// I reduced each one's strength by a factor of 10. 

#declare Smoothed=
 blob {
  threshold .3
  sphere {0,1,-2
   translate 3.2*y
   scale <1.5,1,1.5>
  }
  sphere {0,1,0.6
   translate 3*y
   scale <3,1,3>
  }
  ////
  #declare Mv1=3;
  #declare Sc1=1.5;
  #while (Mv1 >=2.15)
   sphere {0,1,0.06
    translate Mv1*y
    scale <Sc1,1,Sc1>
   }
   #declare Mv1=Mv1-0.085;
   #declare Sc1=Sc1-0.01;
  #end
  ////
  #declare Mv2=2.15;
  #while (Mv2 >=1.2)
   sphere {0,1,0.06
    translate Mv2*y
   }
   #declare Mv2=Mv2-0.095;
  #end
  ////
  #declare Mv3=1.2;
  #declare Sc3=1;
  #while (Mv3 >=0.2)
   sphere {0,1,0.06
    translate Mv3*y
    scale <Sc3,1,Sc3>
   }
   #declare Mv3=Mv3-0.1;
   #declare Sc3=Sc3-0.01;
  #end
  ////
  #declare Mv4=0.2;
  #declare Sc4=0.9;
  #while (Mv4 >= -5.8)
   sphere {0,1,0.06
    translate Mv4*y
    scale <Sc4,1,Sc4>
   }
   #declare Mv4=Mv4-0.1;
   #declare Sc4=Sc4-0.005;
  #end
  ////
  #declare Mv4=-5.2;
  #declare Sc4=0.6;
  #while (Mv4 >= -7)
   sphere {0,1,0.06
    translate Mv4*y
    scale <Sc4,1,Sc4>
   }
   #declare Mv4=Mv4-0.18;
   #declare Sc4=Sc4+0.02;
  #end
  ////
  texture {
   pigment {rgb <.60, .75, .60>}
   finish {
    phong .4
    phong_size .9
    ambient .15
    metallic .6
    diffuse .6
    brilliance .8
   }
  }
 }

#declare Colortone=
 blob {
  threshold .3
  sphere {0,1,-2
   translate 3.2*y
   scale <1.5,1,1.5>
   texture {pigment {Coral} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
  }
  sphere {0,1,0.6
   translate 3*y
   scale <3,1,3>
   texture {pigment {Yellow} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
  }
  ////
  #declare Mv1=3;
  #declare Sc1=1.5;
  #while (Mv1 >=2.15)
   sphere {0,1,0.06
    translate Mv1*y
    scale <Sc1,1,Sc1>
    texture {pigment {MidnightBlue} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
   }
   #declare Mv1=Mv1-0.085;
   #declare Sc1=Sc1-0.01;
  #end
  ////
  #declare Mv2=2.15;
  #while (Mv2 >=1.2)
   sphere {0,1,0.06
    translate Mv2*y
    texture {pigment {SpicyPink} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
   }
   #declare Mv2=Mv2-0.095;
  #end
  ////
  #declare Mv3=1.2;
  #declare Sc3=1;
  #while (Mv3 >=0.2)
   sphere {0,1,0.06
    translate Mv3*y
    scale <Sc3,1,Sc3>
    texture {pigment {Scarlet} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
   }
   #declare Mv3=Mv3-0.1;
   #declare Sc3=Sc3-0.01;
  #end
  ////
  #declare Mv4=0.2;
  #declare Sc4=0.9;
  #while (Mv4 >= -5.8)
   sphere {0,1,0.06
    translate Mv4*y
    scale <Sc4,1,Sc4>
    texture {pigment {Wheat} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
   }
   #declare Mv4=Mv4-0.1;
   #declare Sc4=Sc4-0.005;
  #end
  ////
  #declare Mv4=-5.2;
  #declare Sc4=0.6;
  #while (Mv4 >= -7)
   sphere {0,1,0.06
    translate Mv4*y
    scale <Sc4,1,Sc4>
    texture {pigment {Black} finish {phong .4 phong_size .9 ambient .15 metallic .6 diffuse .6 brilliance .8}}
   }
   #declare Mv4=Mv4-0.18;
   #declare Sc4=Sc4+0.02;
  #end
  ////
 }
 
object {Smoothed scale 5 translate <35,40,0>}
object {Original scale 5 translate <-35,40,0>}
object {Colortone scale 5 translate <0,40,0>}