#declare Unofficial=0;

#if(Unofficial)
    #version unofficial megapov 0.4;
#end

camera{
    location <-.3,3.5,2>
    look_at <.2,2.5,5>
}

light_source{
    <0,3.05,5>
    color <1,.97,.9>*.9
    fade_distance 3
    fade_power 2
    media_attenuation off
}


//Lamp shade material

#declare ShadeMat=
material{
    texture{
        pigment{rgbf 1}
        finish{ambient 0 diffuse 0}
    }
    interior{
        media{
            emission 300
            #if(Unofficial)
                method 3
            #else
                intervals 5
                samples 5,50
                confidence .999
                variance 1/256
            #end
            scattering{5 color 1500 extinction .3 eccentricity .18}
        }
    }
}

//Lamp shade (inner scattering media)

#declare Sphere1=sphere{0,.6}
#declare Sphere2=sphere{0,.59}
difference{
    object{Sphere1} object{Sphere2} plane{y,-.3}
    material{ShadeMat}
    translate <0,.3,0>
    scale <.8,.5,.8>
    translate<0,2.85,5>
    hollow
    no_shadow
}

//Lamp shade (outer surface with finish attributes etc)

#declare Sphere1=sphere{0,.6001}
#declare Sphere2=sphere{0,.5899}
difference{
    object{Sphere1} object{Sphere2} plane{y,-.3001}
    pigment{rgbf <.8,.8,.7,1>*.95}
    finish{specular .3 roughness .05}
    interior{ior 1.4}
    translate <0,.3,0>
    scale <.8,.5,.8>
    translate<0,2.85,5>
    hollow
}

///Lamp base

union{
    cone{<0,2,5>,.25,<0,2.05,5>,.1}
    cone{<0,2.05,5>,.1,<0,2.5,5>,.28}
    cone{<0,2.5,5>,.28,<0,2.7,5>,.1}
    pigment{
        agate
        color_map{[.85 rgb 1][.87 rgb <0,0,.3>]}
        agate_turb .8
        scale .1
    }
    finish{specular .5 roughness .03}
}

//Table
union{
    box{<-1,2,6>,<1,1.85,4>}
    box{<-.99,1.9,5.99>,<-.79,0,5.79>}
    box{<.99,1.9,5.99>,<.79,0,5.79>}
    box{<-.99,1.9,4.01>,<-.79,0,4.31>}
    box{<.99,1.9,4.01>,<.79,0,4.31>}
    pigment{rgb<.7,.5,.25>}
}