/*
Spline Tree Example File 1
Requires MegaPov or Superpatch to run
Parse: 8s Trace: 7min at 640*480 (Pentium II 333MHZ)
*/

//If you are not using MegaPov 0.4 or higher, please remove the line below.
#version unofficial MegaPov 0.4;


camera {
	location <0, 5, -30>
	look_at <0, 3, 0>
	angle 25
}

sky_sphere {
	pigment {
		gradient y
		color_map {
			[ 0 rgb <0.8,0.8,0.9> ]
			[ 0.5 rgb <0.5,0.5,0.6> ]
		}
	}
}

fog {
	fog_type 2
	distance 200
	color rgb 0.9
	fog_offset 0
	fog_alt 2
}

plane {
	y,0
	texture {
		pigment {
			color rgb <0.6,0.6,0.45>
		}
		finish {
			ambient 0.35
			diffuse 0.5
			brilliance 4
			phong 1
		}
	}
}

light_source {
	<99, 100, -100>
	color <1,0.1,0.1>
}
light_source {
	<100, 100, -100>
	color <0.1,1,0.1>
}
light_source {
	<101, 100, -100>
	color <0.1,0.1,1>
}

light_source {
	<0, 5, -32>
	color rgb 0.5
}

//The branch/trunk texture must be defined before calling the macro
//With the exact name below

/*#declare branchtexture = texture {
	pigment {
		color <0.75, 0.70, 0.65>*0.7
	}
	finish {
		ambient 0.0
		diffuse 0.8
		metallic
		specular 0.3
		roughness 0.05
	}
	normal {
		crackle 2
		turbulence 0.5
		scale 0.05
		scale <1,2,1>
	}
} */
#declare branchtexture = 
      texture
      {      
         pigment
         {
            spotted
            color_map
            {
               [ 0.0     rgbft <0.104167, 0.104167, 0.104167, 0.0, 0.0> ]
               [ 0.25    rgbft <0.104167, 0.0, 0.0, 0.0, 0.0> ]
               [ 0.35    rgbft <0.354133, 0.177067, 0.0, 0.0, 0.0> ]
               [ 0.4     rgbft <1.0, 1.0, 1.0, 0.0, 0.0> ]
               [ 1.0     rgbft <0.718733, 0.718733, 0.718733, 0.0, 0.0> ]
            }
            turbulence <0.5, 0.5, 1.0>
            ramp_wave
            scale  <0.1, 0.1, 0.4>
         }      
	finish {
		ambient 0.0
		diffuse 0.8
		metallic
		specular 0.3
		roughness 0.05
	}
         normal
         {
            bozo , 0.2
            turbulence <0.5, 0.5, 1.0>
            ramp_wave
            scale  <0.1, 0.1, 0.4>
         }
      }





#include "leafdefs.inc"
#include "splinetree.inc"
#include "easteregg.inc"

//Very important variables

#declare recursionmax = 5;
#declare rv = array[2] {seed(478),seed(6742)}

//Variables controlling branching
#declare branchlengthturb = 0.3;       // increase this (range 0-1) to make the tree more unweighted ...

//declare divisions = array[5] {10,6,5,4,3} //Big tree
//#declare divisions = array[5] {8,6,4,3,2} //Leafless tree
#declare divisions = array[5] {4,4,3,2,4} //Fast Tree
#declare tdeviance = array[5] {0.5,0.7,0.7,0.7,0.7}
#declare rdeviance = array[5] {80,60,60,50,40}
#declare twigprob = array[6] {0.7,0.8,0.8,0.8,0.8,1}

//Variables controlling spline generation

#declare splinedeviance = array[6] {0.1,0.2,0.3,0.3,0.2,0.1}

//Variables controlling branch creation

#declare branchquality = array[6] {2,3,4,5,5,5}
#declare branchlength = array[6] {2.4,2.0,1.7,0.7,0.5,0.4}
#declare branchwidth = array[7] {0.2,0.15,0.05,0.03,0.015,0.01,0.006}

//Variables allowing speed-ups and memory saving

//#declare simplify = array[6] {no,no,no,no,3,2}
#declare simplify = array[6] {no,no,no,no,no,no}
//#declare simplify = array[6] {1,1,1,1,1,1}

//Variables controlling creation of leaves (or any endpoint object)

#declare leafarray = array[4] {maple1,maple2,maple3,easteregg1}
#declare leafprob = array[4] {0.3,0.3,0.3,0.02}
#declare leafturb = array[4] {1,1,1,0}
#declare leafscale = 0.35;

//Call the macro

#declare feedback = true;

splinetree(0,0,(<0,0,0>),(<0,0,0>))

Statistic ()

//End of file