// Script which counts priority votes
// Copyright 2000 Rune S. Johansen

#macro MacroInitialize (Macro)
   #local X=0;#while(X<dimension_size(Macro,1))#declare Macro[X]=0;#local X=X+1;#end
#end

#declare Logos = dimension_size(Votes,2);
#declare Voters = dimension_size(Votes,1);
#declare Round = 1;
#declare Stop = no;
#declare Points = array[Logos+1]
MacroInitialize(Points)
#declare Excluded = array[Logos+1]
MacroInitialize(Excluded)
#declare LogosLeft = Logos;

#while ( LogosLeft>0 & Round<=Logos )
   
   #debug concat("\n\nROUND ",str(Round,0,0))
   
   MacroInitialize(Points)
   
   // Count votes
   #declare Voter = 0;
   #while (Voter<Voters)
      
      #declare Priority = 0;
      #declare Votefound = no;
      #while (Votefound=no)
         #if (Excluded[ Votes[Voter][Priority] ]=0)
            #declare Votedfor = Votes[Voter][Priority];
            #declare Points[Votedfor] = Points[Votedfor]+1;
            #declare Votefound = yes;
         #else
            #declare Priority = Priority+1;
         #end
      #end
      
      #declare Voter = Voter+1;
   #end
   
   // View counted votes and find out the lowest scores
   
   #debug "\n\nLogo:  "
   #declare Logo = 1;
   #while (Logo<Logos+1)
      #debug concat(str(Logo,-2,0)," ")
      #declare Logo = Logo+1;
   #end
   
   #declare LowestNumber = Voters;
   #declare LowestLogos = array[Logos]
   MacroInitialize(LowestLogos)
   #declare EqualLow = 0;
   
   #debug "\nVotes: "
   #declare Logo = 1;
   #while (Logo<Logos+1)
      
      #debug concat(str(Points[Logo],2,0)," ")
      
      #if (Excluded[Logo]=0)
         #if (Points[Logo]=LowestNumber)
            #declare EqualLow = EqualLow+1;
            #declare LowestLogos[EqualLow-1] = Logo;
         #end
         #if (Points[Logo]<LowestNumber)
            #declare LowestNumber = Points[Logo];
            MacroInitialize(LowestLogos)
            #declare EqualLow = 1;
            #declare LowestLogos[EqualLow-1] = Logo;
         #end
      #end
      
      #declare Logo = Logo+1;
   #end
   
   // Show the lowest scores and exclude them
   #if (LogosLeft>1)
      #debug "\n\nThe following logos are excluded because they got the fewest votes:\n\n"
      #declare X = 0;
      #declare NoMoreExcluded = false;
      #while (NoMoreExcluded=false&X<=Logos)
         #if (LowestLogos[X]>0)
            #debug concat("logo ",str(LowestLogos[X],0,0),", ")
            #declare Excluded[LowestLogos[X]] = 1;
            #declare LogosLeft = LogosLeft-1;
         #else
            #declare NoMoreExcluded = true;
         #end
         #declare X = X+1;
      #end
   #else
      #debug "\n\nTHE WINNER IS:\n\n"
      #declare X = 0;
      #declare NoMoreExcluded = false;
      #while (NoMoreExcluded=false&X<=Logos)
         #if (LowestLogos[X]>0)
            #declare Winner = LowestLogos[X];
            #debug concat("LOGO ",str(Winner,0,0)," !")
            #declare LogosLeft = LogosLeft-1;
            #declare NoMoreExcluded = true;
         #end
         #declare X = X+1;
      #end
   #end
   
   #declare Round = Round+1;
#end

#debug "\n\n"

union {
   #declare Font = "crystal.ttf"
   text {ttf Font, "THE WINNER IS", 0, 0 translate <-3.2,1,6>}
   text {ttf Font, concat("LOGO ",str(Winner,0,0)," !"), 0, 0 translate <-2.2,-0,6>}
   text {ttf Font, "see console text output", 0, 0 translate <-6,-3,10>}
   text {ttf Font, "for the details", 0, 0 translate <-4,-4,10>}
   pigment {color rgb 1} finish {ambient 1}
}