// Tunnel
// Copyright 2000 Rune S. Johansen

#declare Minor = 0.1;
#declare Major = 1.0;
#declare Light = 8.0;
#declare Lights = 50;
#declare Seed1 = seed(1);
#declare Seed2 = seed(1);

#declare X = 0;
#declare Y = 1500;
blob {
   threshold 1
   #while (X<Y)
      sphere {
         0, 0.05,2
         
         translate Minor*x
         rotate 0.106*360*X*z
         translate -Major*x
         rotate 360*X/Y*y
         
         pigment {color <rand(Seed1),rand(Seed1),rand(Seed1)>}
         finish {phong 0.5}
      }
      #declare X = X+1;
   #end
}

#declare X = 0;
#declare Y = Lights;
#while (X<Y)
   union {
      light_source {0, color Light/Y}
      sphere {
         0, 0.01
         no_shadow
         texture {
            pigment {color <rand(Seed2),rand(Seed2),rand(Seed2)>}
            finish {ambient 0.3 diffuse 0.4 phong 0.5 reflection 0.4}
         }
      }
      pigment {color 0}
      translate Major*x
      rotate (X/Y*360+2)*y
   }
   #declare X = X+1;
#end

fog {
   fog_type 1
   distance 0.7
   color rgb 1
}

camera {
   location <-1.02, 0.015, 0>
   angle 60
   look_at  <-0.92, 0.015, 1>
}