// Rotating emitting media, function density
// File: mFunctionMediaD.pov
// Vers: MegaPov 0.3 (POV-Ray 3.1g)
// Date: 13 Jan 2000
// Auth: Philippe Debar philippedebar@hotmail.com
//

global_settings
  {
  assumed_gamma 1.0
  }

camera
  {
  location  <0,0,-10>
  direction 3.5*z
  up        1*y
  right     1*x
  look_at   0
  rotate clock*360*3*<1,2/3,1/3>
  }

sphere
  {
  0, 1.41
  texture{pigment{color rgbt 1}}
  hollow
  interior
    {
    media
      {
      method 3
      aa_threshold .1
      aa_level 3
      emission color rgb 1.75
      intervals 1
      samples   1, 20
      confidence .99
      variance  1/128
      ratio .9
      density
        {
        function {sqrt(sin(x+y))-sqrt(sin(y+z))+sqrt(sin(x+z))}       
        ramp_wave
        color_map
          {
          [0.00 color rgb 0]
          [0.15 color rgb <0,0,.5>]
          [0.30 color rgb 0]
          [0.40 color rgb <1,.7,.1>]
          [0.80 color rgb <1.1,.7,.3>]
          [1.00 color rgb 0]
          }
        }
      density
        {
        spherical
        color_map
          {
          [0.00 color rgb 0]
          [0.10 color rgb .33]
          [1.00 color rgb 1]
          }
        scale 1.4
        }
      }
    }
  }

//eof mFunctionMediaD.pov