// Persistence of Vision Ray Tracer Scene Description File
// File:Aftermath.pov
// Vers: 3.1
// Date: jan 2000
// Auth: Mick Hazelgrove with thanks to Jaime for his cloud technique

#version 3.1;

#include "colors.inc"

global_settings
{
  assumed_gamma 1.0
  max_trace_level 155
}

// ----------------------------------------  

#declare Image_Length = 480;
#declare Image_Height = 640;

camera {
   location <0, 125, -500>
   direction <0, 0,  1.5> 
   right Image_Length/Image_Height*x
   look_at <0,100,150>
   angle 100 
}

sky_sphere
{
  pigment
  {
    gradient y turbulence .3 lambda 3
    color_map { [0.0 color rgb <0,.5,.65>] [1.0 color rgb 1] }
  }
  rotate x*-20
}

light_source{<0, 93000000,0> color rgb<1,1,.875> rotate z*-35 } 


// ---------------------------------------- 

#declare Ground_on = 1;
#declare Sky_on = 1; 
#declare Fog_on = 1 ;                                  
                                    
// ----------------------------------------

#if(Fog_on = 1)

fog {
    fog_type 2 
    distance 7500
    color rgb<.85,.85,.9>
        turbulence .15
        turb_depth 200
                fog_offset 2
                fog_alt 1000
                }
fog {
    fog_type 2 
    distance 2000
    color rgb<.85,.85,.9>
        turbulence 200
        turb_depth 100
                fog_offset 2
                fog_alt 50
                }                
#end

//----------------------------------------
 
#if(Ground_on = 1)

height_field
{
	tga
	"C:\My Documents\Graphics\PovRay\Pov 3.1\levhfdata\Groundhf.tga"
	smooth
    texture{
        pigment{rgb<.75,.75,.3>/1.3}
        normal {granite 50 scale .25}
    }
	translate <-.5, 0.000, -.5>
	rotate x*-10
	scale <750, 75, 250> scale 15
	translate<0,0,4000>
}
height_field
{
	tga
	"C:\My Documents\Graphics\PovRay\Pov 3.1\levhfdata\Groundhf.tga"
	smooth
    texture{
        pigment{rgb<.75,.75,.6>/1.3}
        normal {granite 50 scale .25}
    }
	translate <-.5, 0.000, -.5>
	scale <1250, 100, 250> scale 15
	rotate y*25
	translate<-3500,0,10000>
}
 
#declare Rip = function { 
pigment {
        marble
        color_map {
          [0 color rgb 1]
          [1 color rgb 0]
        }//color map
        turbulence .4
        warp{black_hole <0, 0, 0>, 25 
            repeat<50,0,50> 
            }
        ramp_wave 
        scale 1 
        rotate y*30
    }//pigment 
}//function 

#declare Land3=isosurface {    
function y+(sin(x/5)+noise3d(.5*x,.5*y,0))+(sin(z/6)+noise3d(.5*x,.5*y,.5*z))+(y-Rip(x,y/2,z)/2)
//function y+(sin(x/5)+noise3d(.5*x,.5*y,0))+(sin(z/6)+noise3d(.5*x,.5*y,.5*z))+(-Rip(x,y,z))
   bounded_by{ box {<-5000,-20,-5000>,<5000,20,5000>}}
     sign 2
     threshold  2
     scale 15
    }   

object{Land3 pigment{Tan}}

plane{y,2 texture {  //was 10 with other function
   pigment {color rgbt <0.3,0.3,0.3,.5 >}
       finish {reflection 0.25}  
    }
}
 
#end

// ----------------------------------------

#if (Sky_on = 1)

#declare Cheight=5000; 
#declare Pdist=40;      
#declare Tdist=40;      
#declare Nplanes=80;      
#declare Count=1; 

#declare CldtopCol = color rgb<1,1,.75>;
#declare BaseCol = color rgb<.8,.7,.86>*1.5;

#while (Count<=Nplanes)

#declare FBaseCol=BaseCol*(1-(Count/Nplanes))+CldtopCol*(Count/Nplanes);   

box{<-100000,-0.0000001,-500><100000,0.0,100000>
  texture{
   pigment{
    spotted    
    octaves 9  
    lambda 3
    omega 0.55   
    turbulence 3
    color_map{        
     [0.45 rgbt 1]
     [1.0 FBaseCol filter .5*(Count/Nplanes)] 

    }
   scale 1000000/80    

   }
    
   translate <0,(Cheight+Tdist*Count),0>
  }
  translate <0,(Cheight+Pdist*Count),0>
  
  finish{ambient .25+(1.25*((Count/Nplanes)/1.875)) specular 1}

  hollow
 }
 #declare Count=Count+1;
#end

#end